Running Rails through nix-shell

rails_in_nix-shell.md

Use the following to generate gemset.nix:

nix run nixpkgs.bundix --command bundix

Then run:

nix-shell

The shell will start a mysqld instance that listens on a local Unix socket. It will be killed when the shell is killed.

Next you can run:

rspec

or

rails server

shell.nix

let
  pkgs = import <nixpkgs> {};
  ruby = pkgs.ruby_2_4;
  stdenv = pkgs.stdenv;
  gems = pkgs.bundlerEnv {
    name = "medewerkerportaal-env";
    ruby = ruby;
    gemset = ./gemset.nix;
    gemfile = ./Gemfile;
    lockfile = ./Gemfile.lock;
    groups = ["default" "development" "test"];
  };
in stdenv.mkDerivation {
  name = "medewerkerportaal";
  buildInputs = [ gems ruby ] ++ (with pkgs; [ bundix mariadb ]);
  shellHook = ''
    MYSQL_BASEDIR=${pkgs.mariadb}
    MYSQL_HOME=$PWD/mysql
    MYSQL_DATADIR=$MYSQL_HOME/data
    export MYSQL_UNIX_PORT=$MYSQL_HOME/mysql.sock
    MYSQL_PID_FILE=$MYSQL_HOME/mysql.pid
    mysql_install_db --datadir=$MYSQL_DATADIR --basedir=$MYSQL_BASEDIR --pid-file=$MYSQL_PID_FILE
    mysqld --datadir=$MYSQL_DATADIR --pid-file=$MYSQL_PID_FILE --socket=$MYSQL_UNIX_PORT &
    MYSQL_PID=$!

    finish()
    {
      mysqladmin --socket=$MYSQL_UNIX_PORT shutdown
      kill $MYSQL_PID
      wait $MYSQL_PID
    }

    trap finish EXIT
  '';
}