Core.match like matching with malli

malli-match.clj

(require '[malli.core :as m])

(require '[clojure.string :as str])

(declare ->schema)

(defn variable? [x]
  (and (simple-symbol? x)
       (str/starts-with? (str x) "?")))

(defn ->catn [pattern]
  (into [:catn] (map (fn [elt]
                       (if (variable? elt)
                         [elt :any]
                         [(symbol (str "_" (gensym))) (->schema elt)])) pattern)))

(defn ->schema
  "Coerces pattern into malli schema"
  [pattern]
  (cond
    (vector? pattern) (->catn pattern)
    :else [:= pattern]))

(require '[clojure.walk :as walk])

(defn strip-ignored-keys [m]
  (walk/postwalk (fn [m]
                   (if (map? m)
                     (let [ks (filter variable? (keys m))]
                       (select-keys m ks))
                     m))
                 m))

(defn match [pattern value]
  (-> (m/parse (->schema pattern)
               value)
      strip-ignored-keys))

(match '[1 ?x 3]
       [1 2 3]) ;;=> {?x 2}