openconnect-palo-git edited

README.md

Setting up openconnect with GlobalProtect support on Arch

1. Install the included PKGBUILD.
2. You can now use the command line

Using openconnect with GP support in NetworkManager

1. # pacman -Sy networkmanager-openconnect.
2. Create a VPN connection using openconnect, setting the gateway to whatever you want your gateway to be.
3. Don't connect yet! Edit the file in /etc/NetworkManager/system-connections/ setting protocol to gp.
4. # systemctl restart NetworkManager
5. Connect. Saving your password and 2FA should work.

PKGBUILD

# Maintainer: Serge Bakharev <serge.bakharev@gmail.com>
# Contributor: Bouke van der Bijl <me@bou.ke>

pkgname=openconnect-palo-git
_pkgname=openconnect
pkgver=7.08.r157.ge5fe063a
pkgrel=1
pkgdesc="VPN client for Palo Alto GlobalProtect VPN"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.infradead.org/openconnect.html"
depends=('libxml2' 'gnutls' 'libproxy' 'vpnc' 'krb5' 'lz4' 'pcsclite' 'oath-toolkit')
optdepends=('trousers: TPM support
stoken: RSA SecurID support')
makedepends=('intltool' 'python2' 'git')
options=('!emptydirs')
provides=($_pkgname)
conflicts=($_pkgname)
source=("$pkgname::git+https://github.com/dlenski/$_pkgname.git/")
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's,^[^0-9]*,,;s,\([^-]*-g\),r\1,;s,-,.,g'
}

build() {
  cd $pkgname
  ./autogen.sh
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
      --sbindir=/usr/bin \
      --disable-static
  make V=0
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}