Send current MailPlane email to OmniFocus (with Mailplane and Gmail links as notes)

send-to-omnifocus.scpt

on run {input, parameters}
	
	tell application "Mailplane 3"
		set theEmailUrl to currentURL
		set theGmailUrl to my replace_chars(theEmailUrl, "mailplane://bradley.wright%40digital.cabinet-office.gov.uk/", "https://mail.google.com/mail/ca/u/0/")
		set theSubject to currentTitle
		
		tell application "OmniFocus"
			set theTask to theSubject
			set theNote to theEmailUrl & "
			
" & theGmailUrl
			
			tell quick entry
				set NewTask to make new inbox task with properties {name:theTask, note:theNote}
				select {NewTask}
				open
			end tell
			
			tell application "System Events"
				keystroke tab
			end tell
		end tell
	end tell
	
	return input
end run

on replace_chars(this_text, search_string, replacement_string)
	set AppleScript's text item delimiters to the search_string
	set the item_list to every text item of this_text
	set AppleScript's text item delimiters to the replacement_string
	set this_text to the item_list as string
	set AppleScript's text item delimiters to ""
	return this_text
end replace_chars

send-to-omnifocus2-and-archive-scpt

-- Take the currently open email in MailPlane 3, send it to OmniFocus 2, and archive it

tell application "Mailplane 3"
	set theEmailUrl to currentURL
	set theSubject to currentTitle
	
	tell application "OmniFocus"
		set theTask to theSubject
		set theNote to theEmailUrl
		
		tell quick entry
			make new inbox task with properties {name:theTask, note:theNote}
			open
		end tell
		
		tell application "System Events"
			keystroke tab
		end tell
	end tell
end tell
-- Archive the email I just sent
activate application "Mailplane 3"
tell application "System Events"
	keystroke "E"
end tell

send-to-omnifocus2.scpt

-- this is the OmniFocus 2 Beta compatible version of the above
on run {input, parameters}
	
	tell application "Mailplane 3"
		set theEmailUrl to currentURL
		set theSubject to currentTitle
		
		tell application "OmniFocus"
			set theTask to theSubject
			set theNote to theEmailUrl
			
			tell quick entry
				make new inbox task with properties {name:theTask, note:theNote}
				open
			end tell
			
			tell application "System Events"
				keystroke tab
			end tell
		end tell
	end tell
	
	return input
end run