OpenSCAD trolley fix for titan bags

openscad_trolley.scad

/*

This is a titan bags (https://www.titan-bags.com/) custom part replacement. This piece goes inside the
"telescopic" handle bar after removing two screws. The mechanism is brittle and breaks with repeated
pressure to the main button, leading to an "always locked" position of the telescopic bars.

I've printed this part successfully with PETG 3D printing material via http://3dhubs.com.

*/

$fn=500;

// Helper function to make the main part round around the edges
module cube_round_edges(size, radius)
{
x = size[0]-radius/2;
y = size[1]-radius/2;

    minkowski()
    {
        cube(size=[x,y,size[2]], center=true);
        cylinder(r=radius, center=true);
        // Using a sphere is possible, but will kill performance
        //sphere(r=radius);
    }
}

// Main bar which pushes (unlocks) the trolley mechanism
translate([0,0,3]) {
    difference() {
        cube_round_edges([126, 11, 5], 1);
        // Holes where the screws go
        translate ([35,0,0]) cylinder(h=7, r=4.5, center=true);
        translate ([-35,0,0]) cylinder(h=7, r=4.5, center=true);
    }

}

// Push button with pineapple logo carved
difference() {
    // Center ellipse/button
    resize([35, 15]) cylinder(h=16.5, r=7.5);

    translate ([10,-7,13]) {
        linear_extrude(height = 7, center = false, convexity = 10){
            rotate([0,0,90]) resize([14, 0], auto=true) {
                import("logo-with-flattened-beziers.dxf");
            }
        }
    };
}