Paste a Markdown link to either the selected note in Evernote or any other note into BBEdit.

Insert_Markdown_Link_of_Evernote_Note_into_BBEdit.applescript

property noteLink : missing value

tell application "System Events"
  set theDialog to display dialog "Get Link of selected note or choose other note?" buttons {"Get Selected", "Choose Other"} default button {"Get Selected"}
end tell

--Get Markdown formatted info from Selected Note
if button returned of theDialog is "Get Selected" then
	tell application "Evernote"
		set Evernote_Selection to selection
		if Evernote_Selection is {} then display dialog "Please select a note."
		set noteLink to ""
		
		repeat with i from 1 to the count of Evernote_Selection
			set noteURL to note link of item i of Evernote_Selection
			if noteURL is missing value then
				synchronize
				delay 5
				set noteURL to note link of item i of Evernote_Selection
			end if
			set noteName to title of item i of Evernote_Selection
			set theWikiLink to "[" & noteName & "]" & "(" & noteURL & ")"
			set noteLink to (noteLink) & theWikiLink
		end repeat
	end tell
	
	
	insertText()
	
	
	--Get Markdown formatted info for any note
else
	tell application "Evernote"
		activate
		set listOfNotebooks to {}
		set EVNotebooks to every notebook
		repeat with currentNotebook in EVNotebooks
			set currentNotebookName to (the name of currentNotebook)
			copy currentNotebookName to the end of listOfNotebooks
		end repeat
		set Folders_sorted to my simple_sort(listOfNotebooks)
		
		set SelNotebook to choose from list of Folders_sorted with title "Select Evernote Notebook" with prompt ¬
			"Current Evernote Notebooks" OK button name "OK"
		set EVnotebook to item 1 of SelNotebook
		set listofNotes to {}
		set listofLinks to {}
		set allNotes to every note in notebook EVnotebook
		repeat with currentNote in allNotes
			set currentNoteName to (the title of currentNote)
			copy currentNoteName to the end of listofNotes
			
			set currentNoteURL to (the note link of currentNote)
			copy currentNoteURL to the end of listofLinks
		end repeat
		
		
		set SelNote to ¬
			choose from list of listofNotes with title ¬
				"List of Notes" OK button name "Get Link" cancel button name "Close Window"
		set noteName to SelNote as string
		set notePlacement to my findAll(listofNotes, noteName) as number
		set noteURL to item notePlacement of listofLinks
		
		set noteLink to "[" & noteName & "]" & "(" & noteURL & ")"
		
	end tell
	
	insertText()
	
end if


(* SUBROUTINES *)

on simple_sort(my_list)
	set the index_list to {}
	set the sorted_list to {}
	repeat (the number of items in my_list) times
		set the low_item to ""
		repeat with i from 1 to (number of items in my_list)
			if i is not in the index_list then
				set this_item to item i of my_list as text
				if the low_item is "" then
					set the low_item to this_item
					set the low_item_index to i
				else if this_item comes before the low_item then
					set the low_item to this_item
					set the low_item_index to i
				end if
			end if
		end repeat
		set the end of sorted_list to the low_item
		set the end of the index_list to the low_item_index
	end repeat
	return the sorted_list
end simple_sort

on findAll(lst, val)
	-- HAS (http://applemods.sourceforge.net/mods/Data/List.php)
	local lst, val, res
	try
		if lst's class is not list then error "not a list." number -1704
		if {val} is not in lst then return {}
		set res to {}
		script k
			property l : lst
		end script
		repeat with i from 1 to count of k's l
			if k's l's item i is val then set res's end to i
		end repeat
		return res
	on error eMsg number eNum
		error "Can't find All: " & eMsg number eNum
	end try
end findAll

on insertText()
	tell application "BBEdit"
		activate
		try
			make new word at end of text of document 1 with data noteLink
		on error
			make new text document
			make new word at end of text of document 1 with data noteLink
		end try
	end tell
end insertText