history.clj

(ns hammock-cafe.ui.history
  (:require [io.pedestal.app.protocols :as p]
            [io.pedestal.app.util.log :as log]
            [io.pedestal.app.messages :as msg]))

(def last-page (atom nil))

(def dispatchers (atom {}))

(defn navigate [token]
  (when-let [d (get @dispatchers token)]
    (p/put-message d {msg/topic msg/app-model
                      msg/type :navigate
                      :name (keyword (str "emitter-" (name token)))})))

(def supported? (and js/history (.-pushState js/history)))

(defn navigated [d token]
  (when supported?
    (let [current-token (.-state js/history)]
      (when (not= current-token token)
        (if (nil? @last-page)
          (.replaceState js/history token nil nil)
          (.pushState js/history token nil nil))))
    (reset! last-page token)
    (swap! dispatchers assoc token d)))

(if supported?
  (set! (.-onpopstate js/window) (fn [e] (navigate (.-state e))))
  (log/warn :in :hammock-cafe.ui.history
            :message "HTML 5 History is not supported in this browser!"))