macros-and-multi.clj

;;; Multi Method
(defmethod slack/slash :info [{:keys [response-type]}]
  {:response_type response-type
   :text          (str "TeamGantt for Slack v" (version/current))})

(defmethod slack/slash :default [context]
  (slack/slash (assoc context :command :help)))

;;; Syntactic sugar
(defmacro defslashcmd
  "Define a new supported slash command. Supports defining usage inline
  with the slash command"
  ([name usage bindings & body]
   (let [id     (keyword name)
         usages (if (vector? usage) (into [id] usage) [id usage])]
     `(do
        (apply usage ~usages)
        (defmethod slash ~id
          ~bindings
          ~@body)))))
          
;;; Usage
(defslashcmd today
  "`/tg today` = See what’s on your plate today and update task progress right from Slack."
  [{:keys [api user_id response-type]}]
  (let [{tg :teamgantt} api
        response        (task/get-today tg user_id)]
    (-> response
        (today/message)
        (assoc :response_type response-type))))