locals.tf

locals {
  networks = flatten([
    for network_profile in var.network_profiles : [
      for network in network_profile.networks : {
        cloud_account = network_profile.cloud_account
        name          = network.network
      }
    ]
  ])
}

main.tf

data "vra_fabric_network" "all_networks" {
  for_each = {
    for network in local.networks : "${network.cloud_account}.${network.name}" => network
  }
  filter     = "name eq '${each.value.name}'"
}

resource "vra_network_profile" "this" {
  for_each    = var.network_profiles
  name        = each.key
  description = "Network Profile"
  region_id = var.region_id
  fabric_network_ids = [
    for key, network in data.vra_fabric_network.all_networks :
    network.id
    if key == "${each.value.cloud_account}.${network.name}"
  ]
  isolation_type = each.value.isolation_type
}

terraform.tfvars

network_profiles = {
  "account1" : {
    cloud_account = "account1"
    isolation_type = "NONE"
    networks = [
      {
        network = "network-1"
      },
      {
        network = "network-2"
      }
    ]
  }
}

variables.tf

variable "network_profiles" {
  type = map(object({
    cloud_account  = string
    isolation_type = string
    networks = list(object({
      network = string
    }))
  }))
  description = "List of Network Profiles"
  default     = {}
}