fizzbuzz.hs

-- http://www.parsonsmatt.org/2016/02/27/an_elegant_fizzbuzz.html

import Data.Foldable
import Data.Maybe

type FizzRule = Integer -> Maybe String

rule :: Integer -> String -> FizzRule
rule n m i =
  case i `mod` n of
    0 -> Just m
    _ -> Nothing

fizz = rule 3 "Fizz"
buzz = rule 5 "Buzz"


fizzBuzz :: (Functor f, Foldable t)
            => t (Integer -> Maybe String)
            -> f Integer
            -> f String
fizzBuzz rules = fmap (fromMaybe <$> show <*> ruleSet)
  where
    ruleSet = fold rules


{-  example repl session

λ> :l fizzbuzz.hs
[1 of 1] Compiling Main             ( fizzbuzz.hs, interpreted )
Ok, modules loaded: Main.
λ> fizzBuzz [fizz, buzz]
fizzBuzz [fizz, buzz] :: Functor f => f Integer -> f String

?? now what do ??
-}

You have to wrap the Integer argument in a Functor, specifically a list.

fizzBuzz [fizz, buzz] [10 .. 15]
-- ["Buzz","11","Fizz","13","14","FizzBuzz"]

To get the output you might expect, you can map over the output strings and print them.

mapM_ putStrLn (fizzBuzz [fizz, buzz] [10 .. 15])
-- Buzz
-- 11
-- Fizz
-- 13
-- 14
-- FizzBuzz