sublime-text-3-gtk2 Arch package build

license

Maintainer note:
Sublime Text is free to use, if you want access to the newer builds, with the package
`sublime-text-4-dev` or `sublime-text-dev`, you'll need a paid license.

Buying a license also supports the development of the editor.

---

Sublime Text may be downloaded and evaluated for free, however a license must be purchased for
continued use. Licenses are per-user, rather than per-machine, so you can enjoy Sublime Text on as
many computers and operating systems as you wish with your license.

For more information, please visit https://www.sublimetext.com/buy

PKGBUILD

pkgname=sublime-text-3-gtk2
pkgver=3.3176
pkgrel=1
pkgdesc="Sophisticated text editor for code, html and prose - stable build"
arch=('x86_64')
url='https://www.sublimetext.com/3'
license=('custom')
depends=('libpng' 'gtk2')

replaces=('sublime-text-3-imfix')

conflicts=('sublime-text-4-dev'
           'sublime-text-4'
           'sublime-text-3-imfix'
           'sublime-text-imfix'
           'sublime-text-nightly'
           'sublime-text-dev'
           'sublime-text2')

provides=('sublime-text')

source=(
    "https://download.sublimetext.com/sublime_text_3_build_${pkgver:2}_x64.tar.bz2"
    'LICENSE'
)
sha256sums=('SKIP'
            'SKIP')

package() {
    cd "${srcdir}"

    # Install sublime text 3
    install -dm755 "${pkgdir}/opt"
    cp --preserve=mode -r "sublime_text_3" "${pkgdir}/opt/sublime_text_3"

    # Install icons
    for res in 128x128 16x16 256x256 32x32 48x48; do
        install -dm755 "${pkgdir}/usr/share/icons/hicolor/${res}/apps"
        ln -s "/opt/sublime_text_3/Icon/${res}/sublime-text.png" "${pkgdir}/usr/share/icons/hicolor/${res}/apps/sublime-text.png"
    done

    # Install desktop entry and executable
    install -dm755 "${pkgdir}/usr/share/applications"
    install -Dm644 "sublime_text_3/sublime_text.desktop" "${pkgdir}/usr/share/applications/sublime_text.desktop"
    sed -i 's#/opt/sublime_text/sublime_text#subl#g' "${pkgdir}/usr/share/applications/sublime_text.desktop"
    install -dm755 "${pkgdir}/usr/bin"
    ln -s "/opt/sublime_text_3/sublime_text" "${pkgdir}/usr/bin/subl"

    # Install license file
    install -d "${pkgdir}/usr/share/licenses/${pkgname}"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}