00-README.md

For context, see the discussion at https://discourse.nixos.org/t/request-for-help-packaging-gnome-extensions/2366

desktop-icons.nix

{ stdenv, fetchFromGitLab, meson, ninja, python3, glib }:

stdenv.mkDerivation rec {
  name = "gnome-shell-extension-desktop-icons-${version}";
  version = "19.01.1";

  src = fetchFromGitLab {
    domain = "gitlab.gnome.org";
    owner = "World%2FShellExtensions";
    repo = "desktop-icons";
    rev = "19.01.1";
    sha256 = "03ckn231dwnkda31m722wfav30q0zrkwvv8jh3ndfkzk24dl7s1l";
  };

  nativeBuildInputs = [ meson ninja python3 glib ];

  prePatch = ''
    chmod +x meson_post_install.py
    patchShebangs meson_post_install.py
  '';

  meta = with stdenv.lib; {
    description = "Display desktop icons in GNOME";
    license = licenses.gpl3;
    maintainers = with maintainers; [ callahad ];
    homepage = https://gitlab.gnome.org/World/ShellExtensions/desktop-icons;
  };
}

syncthing-icon.nix

{ stdenv, fetchFromGitHub, glib, zip, unzip, gnome3, systemd }:

stdenv.mkDerivation rec {
  name = "gnome-shell-extension-syncthing-${version}";
  version = "2019-02-18";

  src = fetchFromGitHub {
    owner = "jaystrictor";
    repo = "gnome-shell-extension-syncthing";
    rev = "d90db936371fa9253924c6e726d5614131698389";
    sha256 = "0ilhvcjarf4rsa7plpv6kp919j0jw9swyaydfrla08lh67za4h5m";
  };

  nativeBuildInputs = [ glib zip unzip ];
  buildInputs = [ gnome3.gjs systemd ];

  # TODO: Replace with a proper patch
  prePatch = ''
    substituteInPlace src/systemd.js \
      --replace "/bin/systemctl" "${systemd}/bin/systemctl"
    substituteInPlace src/extension.js \
      --replace "gjs" "${gnome3.gjs}/bin/gjs"
    substituteInPlace install.sh \
      --replace '$HOME/.local/' '$out/'
  '';

  buildPhase = ''
    ./build.sh
  '';

  installPhase = ''
    ./install.sh
  '';

  meta = with stdenv.lib; {
    description = "Display SyncThing status icon in top bar";
    license = licenses.gpl3;
    maintainers = with maintainers; [ callahad ];
    homepage = https://github.com/jaystrictor/gnome-shell-extension-syncthing;
  };
}