Simple DSL expansion

simple-dsl.rkt

#lang racket

(require (for-syntax racket syntax/parse racket/syntax syntax/id-table))

(begin-for-syntax

  (define macro-table (make-free-id-table))

  (define (expand-macro id stx)
    (define transformer (syntax-local-value id))
    (define mark (make-syntax-introducer))
    (mark (transformer (mark stx))))

  (define (recursive-expand stx)
    (syntax-parse stx
      [(macro:id . _)
       #:when (dict-has-key? macro-table #'macro)
       (recursive-expand (expand-macro #'macro stx))]
      [(_ ...)
       (define elems (map recursive-expand (syntax->list stx)))
       (datum->syntax stx elems stx)]
      [_ stx])))

(define-syntax (define-dsl-syntax stx)
  (syntax-parse stx
    [(_ (name:id . args) body:expr)
     #'(begin
         (define-syntax-rule (name . args) body)
         (begin-for-syntax
           (dict-set! macro-table (quote-syntax name) #t)))]))

(module+ test
  (require rackunit)

  (define-syntax (test stx)
    (syntax-parse stx
      [(_ e:expr)
       (define/syntax-parse expanded
         (recursive-expand #'e))
       #'(quote expanded)]))

  (define-dsl-syntax (pred? x) (> 3 x))

  (check-equal?
    (test (or (< 10 x) (pred? y)))
    '(or (< 10 x) (> 3 y)))

  (define-dsl-syntax (other? x) (or (= 2 x) (= 3 x)))

  (check-equal?
    (test (or (other? x) (other? y)))
    '(or (or (= 2 x) (= 3 x))
       (or (= 2 y) (= 3 y)))))