logger_cached.groovy

import groovy.transform.CompileStatic

import java.lang.invoke.*

import static groovyjarjarasm.asm.Opcodes.H_INVOKESTATIC

class Logger {
    private final String name
    Logger(Class cls)  {
        name = cls.name
    }
    void log(String s) {
        System.out.println "logger $name: $s"
    }
}

@CompileStatic
class Helper {
    static CallSite bootstrap(MethodHandles.Lookup lookup,
                              String callType,
                              MethodType type,
                              String className) {
        println 'in bootstrap'
        Logger logger = new Logger(Class.forName(className))
        MethodHandle mh = MethodHandles.constant(Logger, logger)
        new ConstantCallSite(mh)
    }
}

class MyClass {
    @groovyx.ast.bytecode.Bytecode
    static void testLogging(String message) {
        invokedynamic 'getLogger', '()LLogger;',
                [H_INVOKESTATIC, 'Helper', 'bootstrap',
                 [CallSite, MethodHandles.Lookup, String, MethodType, String]],
                'MyClass'
        aload_0
        invokevirtual 'Logger.log', '(Ljava/lang/String;)V'
        return
    }
}

2.times { MyClass.testLogging('da message') }