Define all parent directories of a path in a prototype file for Sun's pkgmk tool creating Solaris packages.

sunpkg-mkdir.el

(defun sunpkg-mkdir ()
  "Define all parent directories of a path in a prototype file
for Sun's pkgmk tool creating Solaris packages.  When the cursor
is in a line containing the following crontab definition

  e cron var/spool/cron/crontabs/root=src/crontab ? ? ?

the function will insert the following directories in front of if

  d cron var ? ? ?
  d cron var/spool ? ? ?
  d cron var/spool/cron ? ? ?
  d cron var/spool/cron/crontabs ? ? ?
"
  (interactive)
  (save-excursion
    (beginning-of-line)
    (if (looking-at "^[de]\\s-+\\(\\w+\\)\\s-+\\([^ =]+\\)")
        (let ((path nil)
              (class (match-string 1)))
          (dolist (element (butlast (split-string (match-string 2) "/")))
            (setq path (if path
                           (concat path "/" element)
                         element))
            (insert "d " class " " path " ? ? ?")
            (newline))))))