vmutt

#!/usr/bin/perl

# usage:
# vmutt [maildir] [command]
# eg.
# vmutt ~/mail/flagged "mutt -f ~/mail/flagged"

use warnings;
use strict;
use File::Basename qw/basename dirname/;
use File::Spec;

my $dir = $ARGV[0];
my $cmd = $ARGV[1];

die("first argument must be maildir full of symlinks") unless -d "$dir/cur";

my @orglinks = <$dir/cur/*>;
my @orgdests = map { readlink } @orglinks;
my %original;

@original{@orgdests} = @orglinks;

my $ret = system($ARGV[1]);
#exit($ret) if $ret;

my @newlinks = <$dir/cur/*>;
my @newdests = map { readlink } @newlinks;

for my $i (0..$#newlinks) {
    my $link = $newlinks[$i];
    my $dest = $newdests[$i];

    if (exists $original{$dest}) {
        if ($original{$dest} ne $link) {
            my $newname = File::Spec->catfile(
                dirname($dest), 
                basename($link)
            );
            print "rename: $dest -> $newname\n";
            rename($dest, $newname);
        }
        delete $original{$dest};
    } else {
        die "WTF? where did $dest come from?!";
    }
}

for (keys %original) {
    print "delete: $_\n";
    unlink($_);
}

backup of http://mafipulation.org/static/vmutt