led_on_http.ino

// Based on https://github.com/esp8266/Arduino/blob/master/libraries/ESP8266WebServer/examples/HelloServer/HelloServer.ino

// Description
// Control built-in led in NodeMCU.
// Edit your SSID and PASSWD (line 19, 20)

// Usage
// /      -> blink shortly
// /on    -> turn led on
// /off   -> turn led off
// /blink -> blink twice

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>

#ifndef STASSID
#define STASSID "SSID"
#define STAPSK  "PASSWD"
#endif

const char* ssid = STASSID;
const char* password = STAPSK;

ESP8266WebServer server(80);

const int led = LED_BUILTIN;

void handleRoot() {
  digitalWrite(led, 0);
  server.send(200, "text/plain", "hello from esp8266!\r\n");
  digitalWrite(led, 1);
}

void handleNotFound() {
  server.send(404, "text/plain", "File Not Found\n\n");
}

void setup(void) {
  pinMode(led, OUTPUT);
  digitalWrite(led, 1);
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp8266")) {
    Serial.println("MDNS responder started");
  }

  server.on("/", handleRoot);

  server.on("/on", []() {
    digitalWrite(led, 0);
    server.send(200, "text/plain", "on");
  });

  server.on("/off", []() {
    digitalWrite(led, 1);
    server.send(200, "text/plain", "off");
  });

  server.on("/blink", []() {
    server.send(200, "text/plain", "blink");
    digitalWrite(led, 0);
    delay(300);
    digitalWrite(led, 1);
    delay(300);
    digitalWrite(led, 0);
    delay(300);
    digitalWrite(led, 1);
    delay(300);
  });

  server.onNotFound(handleNotFound);

  server.begin();
  Serial.println("HTTP server started");
}

void loop(void) {
  server.handleClient();
  MDNS.update();
}