TinyFugue GMCP negotiation

gistfile1.txt

; -*- folded-file: t -*-

; {{{ gmcp_handler

/def gmcp_handler = \
	/if (gmcp_debug) /echo % gmcp: %{*} %; /endif %;\
	/if ({1} !~ "Char.Vitals") \
		/echo % gmcp unrecognised %;\
		/return %;\
	/endif %;\
	/shift %;\
	/let s $[substr({*}, 1, -1)] %;\
	/while (strlen(s)) \
		/splitat , %{s} %;\
		/test s := {P2} %;\
		/splitat : %{P1} %;\
		/let var $[substr({P1}, 1, -1)] %;\
		/if (var =~ "hp") /set hpcur %P2 %; /endif %;\
		/if (var =~ "maxhp") /set hpmax %P2 %; /endif %;\
		/if (var =~ "gp") /set gpcur %P2 %; /endif %;\
		/if (var =~ "maxgp") /set gpmax %P2 %; /endif %;\
		/if (var =~ "xp") /set xpcur %P2 %; /endif %;\
		/if (var =~ "burden") /set burden %P2 %; /endif %;\
	/done %;\
	/status_redraw

; }}}
; {{{ /gmcp {0|off|1|on}
/def gmcp = \
	/if (!{#}) /echo gmcp=%{gmcp} %; /return %; /endif %;\
	/set gmcp %{*} %;\
	/if (gmcp) \
		/def -hGMCP gmcp_hook = /gmcp_handler %%{*} %;\
		/test gmcp("core.supports.set [ \\"Char.Vitals\\" ]") %;\
	/else \
		/undef gmcp_hook %;\
		/test gmcp("core.supports.set [ ]") %;\
	/endif
; }}}

/set gmcp_debug 1
/gmcp on