Resource.hs

{-# LANGUAGE ScopedTypeVariables #-}

-- | A ResourceT-based way to use connections with conduit.

module Data.Conduit.Network.Resource where

import qualified Network.Socket as NS
import Control.Exception
import Control.Monad.IO.Class
import Control.Monad.Trans.Resource
import Data.Streaming.Network
import Data.Streaming.Network.Internal
import Network.Socket.ByteString (sendAll)

-- | Allocate a TCP client that will be close automatically by the
-- resource monad.
allocateTCPClient ::
     (MonadIO m, MonadResource m)
  => ClientSettings
  -> m (Either IOException (ReleaseKey, AppData))
allocateTCPClient (ClientSettings port host addrFamily readBufferSize) = do
  result <- allocate (try allocator) freer
  case result of
    (releaseKey, Right appData) -> pure (Right (releaseKey, appData))
    (_, Left ioexception) -> pure (Left ioexception)
  where
    allocator = do
      (s, address) <- liftIO (getSocketFamilyTCP host port addrFamily)
      pure
        AppData
          { appRead' = safeRecv s readBufferSize
          , appWrite' = sendAll s
          , appSockAddr' = address
          , appLocalAddr' = Nothing
          , appCloseConnection' = NS.close s
          , appRawSocket' = Just s
          }
    freer :: Either IOException AppData -> IO ()
    freer = either (const (pure ())) appCloseConnection'