Improving the Tutorial: Using the Same View for Multiple Actions in CFWheels

edit.cfm

<cfoutput>
 
<h1>Edit User #user.name#</h1>
 
<cfif flashKeyExists("success")>
    <p class="success">#flash("success")#</p>
</cfif>
 
#startFormTag(action="update")#
 
#textField(objectName="user", property="name", label="Name")#
#textField(objectName="user", property="email", label="Email")#
#passwordField(objectName="user", property="password", label="Password")#
<div>
    #hiddenField(objectName="user", property="id")#
    #submitTag()#
</div>
 
#endFormTag()#
 
</cfoutput>

form.cfm

<cfparam name="header" type="string">
<cfparam name="user">
<cfparam name="formAction" type="string">
<cfparam name="submitLabel" type="string">
 
<cfoutput>
 
<h1>#header#</h1>
 
<cfif flashKeyExists("success")>
    <p class="success">#flash("success")#</p>
</cfif>
 
#startFormTag(action=formAction)#
 
#textField(objectName="user", property="name", label="Name")#
#textField(objectName="user", property="email", label="Email")#
#passwordField(objectName="user", property="password", label="Password")#
<div>
    <cfif not user.isNew()>
        #hiddenField(objectName="user", property="id")#
    </cfif>
    #submitTag(value=submitLabel)#
</div>
 
#endFormTag()#
 
</cfoutput>

new.cfm

<cfoutput>
 
<h1>Create a New User</h1>
 
#startFormTag(action="create")#
 
#textField(objectName="user", property="name", label="Name")#
#textField(objectName="user", property="email", label="Email")#
#passwordField(objectName="user", property="password", label="Password")#
<div>#submitTag()#</div>
 
#endFormTag()#
 
</cfoutput>

Users.cfc

<cffunction name="add">
    <cfset user = model("user").new()>
    <cfset header = "Create a New User">
    <cfset formAction = "create">
    <cfset submitLabel = "Create">
    <cfset renderPage(template="form")>
</cffunction>

<cffunction name="edit">
    <cfset user = model("user").findByKey(params.key)>
    <cfset header = "Edit User #user.name#">
    <cfset formAction = "update">
    <cfset submitLabel = "Save changes">
    <cfset renderPage(template="form")>
</cffunction>