Created
October 14, 2018 04:11
-
-
Save chrisli30/777d9d21986628939b3eeb7b45245bae to your computer and use it in GitHub Desktop.
Created using remix-ide: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://remix.ethereum.org/#version=soljson-v0.4.24+commit.e67f0147.js&optimize=true&gist=
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./ERC20Basic.sol"; | |
import "./SafeMath.sol"; | |
/** | |
* @title Basic token | |
* @dev Basic version of StandardToken, with no allowances. | |
*/ | |
contract BasicToken is ERC20Basic { | |
using SafeMath for uint256; | |
mapping(address => uint256) internal balances; | |
uint256 internal totalSupply_; | |
/** | |
* @dev Total number of tokens in existence | |
*/ | |
function totalSupply() public view returns (uint256) { | |
return totalSupply_; | |
} | |
/** | |
* @dev Transfer token for a specified address | |
* @param _to The address to transfer to. | |
* @param _value The amount to be transferred. | |
*/ | |
function transfer(address _to, uint256 _value) public returns (bool) { | |
require(_value <= balances[msg.sender]); | |
require(_to != address(0)); | |
balances[msg.sender] = balances[msg.sender].sub(_value); | |
balances[_to] = balances[_to].add(_value); | |
emit Transfer(msg.sender, _to, _value); | |
return true; | |
} | |
/** | |
* @dev Gets the balance of the specified address. | |
* @param _owner The address to query the the balance of. | |
* @return An uint256 representing the amount owned by the passed address. | |
*/ | |
function balanceOf(address _owner) public view returns (uint256) { | |
return balances[_owner]; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.23; | |
import "./StandardToken.sol"; | |
import "./DetailedERC20.sol"; | |
import "./BurnableToken.sol"; | |
contract BMEXToken is StandardToken, DetailedERC20, BurnableToken { | |
constructor( | |
string _name, | |
string _symbol, | |
uint8 _decimals, | |
uint256 _amount | |
) | |
BurnableToken() | |
DetailedERC20(_name, _symbol, _decimals) | |
StandardToken() | |
public | |
{ | |
require(_amount > 0, "amount has to be greater than 0"); | |
totalSupply_ = _amount.mul(10 ** uint256(_decimals)); | |
balances[msg.sender] = totalSupply_; | |
emit Transfer(address(0), msg.sender, totalSupply_); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./BasicToken.sol"; | |
/** | |
* @title Burnable Token | |
* @dev Token that can be irreversibly burned (destroyed). | |
*/ | |
contract BurnableToken is BasicToken { | |
event Burn(address indexed burner, uint256 value); | |
/** | |
* @dev Burns a specific amount of tokens. | |
* @param _value The amount of token to be burned. | |
*/ | |
function burn(uint256 _value) public { | |
_burn(msg.sender, _value); | |
} | |
function _burn(address _who, uint256 _value) internal { | |
require(_value <= balances[_who]); | |
// no need to require value <= totalSupply, since that would imply the | |
// sender's balance is greater than the totalSupply, which *should* be an assertion failure | |
balances[_who] = balances[_who].sub(_value); | |
totalSupply_ = totalSupply_.sub(_value); | |
emit Burn(_who, _value); | |
emit Transfer(_who, address(0), _value); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./MintableToken.sol"; | |
/** | |
* @title Capped token | |
* @dev Mintable token with a token cap. | |
*/ | |
contract CappedToken is MintableToken { | |
uint256 public cap; | |
constructor(uint256 _cap) public { | |
require(_cap > 0); | |
cap = _cap; | |
} | |
/** | |
* @dev Function to mint tokens | |
* @param _to The address that will receive the minted tokens. | |
* @param _amount The amount of tokens to mint. | |
* @return A boolean that indicates if the operation was successful. | |
*/ | |
function mint( | |
address _to, | |
uint256 _amount | |
) | |
public | |
returns (bool) | |
{ | |
require(totalSupply_.add(_amount) <= cap); | |
return super.mint(_to, _amount); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./ERC20.sol"; | |
/** | |
* @title DetailedERC20 token | |
* @dev The decimals are only for visualization purposes. | |
* All the operations are done using the smallest and indivisible token unit, | |
* just as on Ethereum all the operations are done in wei. | |
*/ | |
contract DetailedERC20 is ERC20 { | |
string public name; | |
string public symbol; | |
uint8 public decimals; | |
constructor(string _name, string _symbol, uint8 _decimals) public { | |
name = _name; | |
symbol = _symbol; | |
decimals = _decimals; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./ERC20Basic.sol"; | |
/** | |
* @title ERC20 interface | |
* @dev see https://github.com/ethereum/EIPs/issues/20 | |
*/ | |
contract ERC20 is ERC20Basic { | |
function allowance(address _owner, address _spender) | |
public view returns (uint256); | |
function transferFrom(address _from, address _to, uint256 _value) | |
public returns (bool); | |
function approve(address _spender, uint256 _value) public returns (bool); | |
event Approval( | |
address indexed owner, | |
address indexed spender, | |
uint256 value | |
); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
/** | |
* @title ERC20Basic | |
* @dev Simpler version of ERC20 interface | |
* See https://github.com/ethereum/EIPs/issues/179 | |
*/ | |
contract ERC20Basic { | |
function totalSupply() public view returns (uint256); | |
function balanceOf(address _who) public view returns (uint256); | |
function transfer(address _to, uint256 _value) public returns (bool); | |
event Transfer(address indexed from, address indexed to, uint256 value); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./StandardToken.sol"; | |
import "../../ownership/Ownable.sol"; | |
/** | |
* @title Mintable token | |
* @dev Simple ERC20 Token example, with mintable token creation | |
* Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol | |
*/ | |
contract MintableToken is StandardToken, Ownable { | |
event Mint(address indexed to, uint256 amount); | |
event MintFinished(); | |
bool public mintingFinished = false; | |
modifier canMint() { | |
require(!mintingFinished); | |
_; | |
} | |
modifier hasMintPermission() { | |
require(msg.sender == owner); | |
_; | |
} | |
/** | |
* @dev Function to mint tokens | |
* @param _to The address that will receive the minted tokens. | |
* @param _amount The amount of tokens to mint. | |
* @return A boolean that indicates if the operation was successful. | |
*/ | |
function mint( | |
address _to, | |
uint256 _amount | |
) | |
public | |
hasMintPermission | |
canMint | |
returns (bool) | |
{ | |
totalSupply_ = totalSupply_.add(_amount); | |
balances[_to] = balances[_to].add(_amount); | |
emit Mint(_to, _amount); | |
emit Transfer(address(0), _to, _amount); | |
return true; | |
} | |
/** | |
* @dev Function to stop minting new tokens. | |
* @return True if the operation was successful. | |
*/ | |
function finishMinting() public onlyOwner canMint returns (bool) { | |
mintingFinished = true; | |
emit MintFinished(); | |
return true; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./StandardToken.sol"; | |
import "../../lifecycle/Pausable.sol"; | |
/** | |
* @title Pausable token | |
* @dev StandardToken modified with pausable transfers. | |
**/ | |
contract PausableToken is StandardToken, Pausable { | |
function transfer( | |
address _to, | |
uint256 _value | |
) | |
public | |
whenNotPaused | |
returns (bool) | |
{ | |
return super.transfer(_to, _value); | |
} | |
function transferFrom( | |
address _from, | |
address _to, | |
uint256 _value | |
) | |
public | |
whenNotPaused | |
returns (bool) | |
{ | |
return super.transferFrom(_from, _to, _value); | |
} | |
function approve( | |
address _spender, | |
uint256 _value | |
) | |
public | |
whenNotPaused | |
returns (bool) | |
{ | |
return super.approve(_spender, _value); | |
} | |
function increaseApproval( | |
address _spender, | |
uint _addedValue | |
) | |
public | |
whenNotPaused | |
returns (bool success) | |
{ | |
return super.increaseApproval(_spender, _addedValue); | |
} | |
function decreaseApproval( | |
address _spender, | |
uint _subtractedValue | |
) | |
public | |
whenNotPaused | |
returns (bool success) | |
{ | |
return super.decreaseApproval(_spender, _subtractedValue); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./MintableToken.sol"; | |
import "../../access/rbac/RBAC.sol"; | |
/** | |
* @title RBACMintableToken | |
* @author Vittorio Minacori (@vittominacori) | |
* @dev Mintable Token, with RBAC minter permissions | |
*/ | |
contract RBACMintableToken is MintableToken, RBAC { | |
/** | |
* A constant role name for indicating minters. | |
*/ | |
string public constant ROLE_MINTER = "minter"; | |
/** | |
* @dev override the Mintable token modifier to add role based logic | |
*/ | |
modifier hasMintPermission() { | |
checkRole(msg.sender, ROLE_MINTER); | |
_; | |
} | |
/** | |
* @dev add a minter role to an address | |
* @param _minter address | |
*/ | |
function addMinter(address _minter) public onlyOwner { | |
addRole(_minter, ROLE_MINTER); | |
} | |
/** | |
* @dev remove a minter role from an address | |
* @param _minter address | |
*/ | |
function removeMinter(address _minter) public onlyOwner { | |
removeRole(_minter, ROLE_MINTER); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./ERC20Basic.sol"; | |
import "./ERC20.sol"; | |
/** | |
* @title SafeERC20 | |
* @dev Wrappers around ERC20 operations that throw on failure. | |
* To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract, | |
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc. | |
*/ | |
library SafeERC20 { | |
function safeTransfer( | |
ERC20Basic _token, | |
address _to, | |
uint256 _value | |
) | |
internal | |
{ | |
require(_token.transfer(_to, _value)); | |
} | |
function safeTransferFrom( | |
ERC20 _token, | |
address _from, | |
address _to, | |
uint256 _value | |
) | |
internal | |
{ | |
require(_token.transferFrom(_from, _to, _value)); | |
} | |
function safeApprove( | |
ERC20 _token, | |
address _spender, | |
uint256 _value | |
) | |
internal | |
{ | |
require(_token.approve(_spender, _value)); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
/** | |
* @title SafeMath | |
* @dev Math operations with safety checks that throw on error | |
*/ | |
library SafeMath { | |
/** | |
* @dev Multiplies two numbers, throws on overflow. | |
*/ | |
function mul(uint256 _a, uint256 _b) internal pure returns (uint256 c) { | |
// Gas optimization: this is cheaper than asserting 'a' not being zero, but the | |
// benefit is lost if 'b' is also tested. | |
// See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522 | |
if (_a == 0) { | |
return 0; | |
} | |
c = _a * _b; | |
assert(c / _a == _b); | |
return c; | |
} | |
/** | |
* @dev Integer division of two numbers, truncating the quotient. | |
*/ | |
function div(uint256 _a, uint256 _b) internal pure returns (uint256) { | |
// assert(_b > 0); // Solidity automatically throws when dividing by 0 | |
// uint256 c = _a / _b; | |
// assert(_a == _b * c + _a % _b); // There is no case in which this doesn't hold | |
return _a / _b; | |
} | |
/** | |
* @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend). | |
*/ | |
function sub(uint256 _a, uint256 _b) internal pure returns (uint256) { | |
assert(_b <= _a); | |
return _a - _b; | |
} | |
/** | |
* @dev Adds two numbers, throws on overflow. | |
*/ | |
function add(uint256 _a, uint256 _b) internal pure returns (uint256 c) { | |
c = _a + _b; | |
assert(c >= _a); | |
return c; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./BurnableToken.sol"; | |
import "./StandardToken.sol"; | |
/** | |
* @title Standard Burnable Token | |
* @dev Adds burnFrom method to ERC20 implementations | |
*/ | |
contract StandardBurnableToken is BurnableToken, StandardToken { | |
/** | |
* @dev Burns a specific amount of tokens from the target address and decrements allowance | |
* @param _from address The address which you want to send tokens from | |
* @param _value uint256 The amount of token to be burned | |
*/ | |
function burnFrom(address _from, uint256 _value) public { | |
require(_value <= allowed[_from][msg.sender]); | |
// Should https://github.com/OpenZeppelin/zeppelin-solidity/issues/707 be accepted, | |
// this function needs to emit an event with the updated approval. | |
allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value); | |
_burn(_from, _value); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./BasicToken.sol"; | |
import "./ERC20.sol"; | |
/** | |
* @title Standard ERC20 token | |
* | |
* @dev Implementation of the basic standard token. | |
* https://github.com/ethereum/EIPs/issues/20 | |
* Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol | |
*/ | |
contract StandardToken is ERC20, BasicToken { | |
mapping (address => mapping (address => uint256)) internal allowed; | |
/** | |
* @dev Transfer tokens from one address to another | |
* @param _from address The address which you want to send tokens from | |
* @param _to address The address which you want to transfer to | |
* @param _value uint256 the amount of tokens to be transferred | |
*/ | |
function transferFrom( | |
address _from, | |
address _to, | |
uint256 _value | |
) | |
public | |
returns (bool) | |
{ | |
require(_value <= balances[_from]); | |
require(_value <= allowed[_from][msg.sender]); | |
require(_to != address(0)); | |
balances[_from] = balances[_from].sub(_value); | |
balances[_to] = balances[_to].add(_value); | |
allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value); | |
emit Transfer(_from, _to, _value); | |
return true; | |
} | |
/** | |
* @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender. | |
* Beware that changing an allowance with this method brings the risk that someone may use both the old | |
* and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this | |
* race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards: | |
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729 | |
* @param _spender The address which will spend the funds. | |
* @param _value The amount of tokens to be spent. | |
*/ | |
function approve(address _spender, uint256 _value) public returns (bool) { | |
allowed[msg.sender][_spender] = _value; | |
emit Approval(msg.sender, _spender, _value); | |
return true; | |
} | |
/** | |
* @dev Function to check the amount of tokens that an owner allowed to a spender. | |
* @param _owner address The address which owns the funds. | |
* @param _spender address The address which will spend the funds. | |
* @return A uint256 specifying the amount of tokens still available for the spender. | |
*/ | |
function allowance( | |
address _owner, | |
address _spender | |
) | |
public | |
view | |
returns (uint256) | |
{ | |
return allowed[_owner][_spender]; | |
} | |
/** | |
* @dev Increase the amount of tokens that an owner allowed to a spender. | |
* approve should be called when allowed[_spender] == 0. To increment | |
* allowed value is better to use this function to avoid 2 calls (and wait until | |
* the first transaction is mined) | |
* From MonolithDAO Token.sol | |
* @param _spender The address which will spend the funds. | |
* @param _addedValue The amount of tokens to increase the allowance by. | |
*/ | |
function increaseApproval( | |
address _spender, | |
uint256 _addedValue | |
) | |
public | |
returns (bool) | |
{ | |
allowed[msg.sender][_spender] = ( | |
allowed[msg.sender][_spender].add(_addedValue)); | |
emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]); | |
return true; | |
} | |
/** | |
* @dev Decrease the amount of tokens that an owner allowed to a spender. | |
* approve should be called when allowed[_spender] == 0. To decrement | |
* allowed value is better to use this function to avoid 2 calls (and wait until | |
* the first transaction is mined) | |
* From MonolithDAO Token.sol | |
* @param _spender The address which will spend the funds. | |
* @param _subtractedValue The amount of tokens to decrease the allowance by. | |
*/ | |
function decreaseApproval( | |
address _spender, | |
uint256 _subtractedValue | |
) | |
public | |
returns (bool) | |
{ | |
uint256 oldValue = allowed[msg.sender][_spender]; | |
if (_subtractedValue >= oldValue) { | |
allowed[msg.sender][_spender] = 0; | |
} else { | |
allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue); | |
} | |
emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]); | |
return true; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./SafeERC20.sol"; | |
/** | |
* @title TokenTimelock | |
* @dev TokenTimelock is a token holder contract that will allow a | |
* beneficiary to extract the tokens after a given release time | |
*/ | |
contract TokenTimelock { | |
using SafeERC20 for ERC20Basic; | |
// ERC20 basic token contract being held | |
ERC20Basic public token; | |
// beneficiary of tokens after they are released | |
address public beneficiary; | |
// timestamp when token release is enabled | |
uint256 public releaseTime; | |
constructor( | |
ERC20Basic _token, | |
address _beneficiary, | |
uint256 _releaseTime | |
) | |
public | |
{ | |
// solium-disable-next-line security/no-block-members | |
require(_releaseTime > block.timestamp); | |
token = _token; | |
beneficiary = _beneficiary; | |
releaseTime = _releaseTime; | |
} | |
/** | |
* @notice Transfers tokens held by timelock to beneficiary. | |
*/ | |
function release() public { | |
// solium-disable-next-line security/no-block-members | |
require(block.timestamp >= releaseTime); | |
uint256 amount = token.balanceOf(address(this)); | |
require(amount > 0); | |
token.safeTransfer(beneficiary, amount); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
/* solium-disable security/no-block-members */ | |
pragma solidity ^0.4.24; | |
import "./ERC20Basic.sol"; | |
import "./SafeERC20.sol"; | |
import "../../ownership/Ownable.sol"; | |
import "../../math/SafeMath.sol"; | |
/** | |
* @title TokenVesting | |
* @dev A token holder contract that can release its token balance gradually like a | |
* typical vesting scheme, with a cliff and vesting period. Optionally revocable by the | |
* owner. | |
*/ | |
contract TokenVesting is Ownable { | |
using SafeMath for uint256; | |
using SafeERC20 for ERC20Basic; | |
event Released(uint256 amount); | |
event Revoked(); | |
// beneficiary of tokens after they are released | |
address public beneficiary; | |
uint256 public cliff; | |
uint256 public start; | |
uint256 public duration; | |
bool public revocable; | |
mapping (address => uint256) public released; | |
mapping (address => bool) public revoked; | |
/** | |
* @dev Creates a vesting contract that vests its balance of any ERC20 token to the | |
* _beneficiary, gradually in a linear fashion until _start + _duration. By then all | |
* of the balance will have vested. | |
* @param _beneficiary address of the beneficiary to whom vested tokens are transferred | |
* @param _cliff duration in seconds of the cliff in which tokens will begin to vest | |
* @param _start the time (as Unix time) at which point vesting starts | |
* @param _duration duration in seconds of the period in which the tokens will vest | |
* @param _revocable whether the vesting is revocable or not | |
*/ | |
constructor( | |
address _beneficiary, | |
uint256 _start, | |
uint256 _cliff, | |
uint256 _duration, | |
bool _revocable | |
) | |
public | |
{ | |
require(_beneficiary != address(0)); | |
require(_cliff <= _duration); | |
beneficiary = _beneficiary; | |
revocable = _revocable; | |
duration = _duration; | |
cliff = _start.add(_cliff); | |
start = _start; | |
} | |
/** | |
* @notice Transfers vested tokens to beneficiary. | |
* @param _token ERC20 token which is being vested | |
*/ | |
function release(ERC20Basic _token) public { | |
uint256 unreleased = releasableAmount(_token); | |
require(unreleased > 0); | |
released[_token] = released[_token].add(unreleased); | |
_token.safeTransfer(beneficiary, unreleased); | |
emit Released(unreleased); | |
} | |
/** | |
* @notice Allows the owner to revoke the vesting. Tokens already vested | |
* remain in the contract, the rest are returned to the owner. | |
* @param _token ERC20 token which is being vested | |
*/ | |
function revoke(ERC20Basic _token) public onlyOwner { | |
require(revocable); | |
require(!revoked[_token]); | |
uint256 balance = _token.balanceOf(address(this)); | |
uint256 unreleased = releasableAmount(_token); | |
uint256 refund = balance.sub(unreleased); | |
revoked[_token] = true; | |
_token.safeTransfer(owner, refund); | |
emit Revoked(); | |
} | |
/** | |
* @dev Calculates the amount that has already vested but hasn't been released yet. | |
* @param _token ERC20 token which is being vested | |
*/ | |
function releasableAmount(ERC20Basic _token) public view returns (uint256) { | |
return vestedAmount(_token).sub(released[_token]); | |
} | |
/** | |
* @dev Calculates the amount that has already vested. | |
* @param _token ERC20 token which is being vested | |
*/ | |
function vestedAmount(ERC20Basic _token) public view returns (uint256) { | |
uint256 currentBalance = _token.balanceOf(address(this)); | |
uint256 totalBalance = currentBalance.add(released[_token]); | |
if (block.timestamp < cliff) { | |
return 0; | |
} else if (block.timestamp >= start.add(duration) || revoked[_token]) { | |
return totalBalance; | |
} else { | |
return totalBalance.mul(block.timestamp.sub(start)).div(duration); | |
} | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment