Generate an embedded JSON list with arbitrary transformations using JsonBuilder

gistfile1.groovy

import groovy.json.*

// A list of things we want to include in our json output.
// Here it's a list of maps, but this could be a list of beans.
things = [[id:2, name:'asdf'], [id:3, name:'foo'], [id:5, name:'bar']]

// JsonBuilder is pretty cool!
def json = new JsonBuilder()

json {
    // It's easy to add single properties like this...
    "a" "b"
    "c" 123
    
    // ...and to add a list of objects without changing them...
    "things" things
    
    // ...but if you want to apply some transformation to each
    // object in the list before outputting it, you can return
    // a list of closures. Magic!
    "transformed_things" things.collect { t ->
        return {"${t.name}" "${t.id}"}
    }
}

println json.toString()

// {"a":"b","c":123,
// "things":[{"id":2,"name":"asdf"},{"id":3,"name":"foo"},{"id":5,"name":"bar"}],
// "transformed_things":[{"asdf":"2"},{"foo":"3"},{"bar":"5"}]}