ycombinator-step1.clj

(ns step1)

(defn fact
  [n]
  (if (< n 2) 1 (* n (fact (dec n)))))

;; (fact 5) => 120

ycombinator-step2.clj

(ns step2)

(defn fact
  [f]
  (fn [n]
    (if (< n 2) 1 (* n ((f f) (dec n))))))

;; ((fact fact) 5) => 120

ycombinator-step3.clj

(ns step3)

(defn yrecur
  [f]
  (f f))

(def fact
     (yrecur (fn [f]
               (fn [n]
                 (if (< n 2) 1 (* n ((f f) (dec n))))))))

;; (fact 5) => 120

ycombinator-step4.clj

(ns step4)

(defn yrecur
  [f]
  (f f))

(def fact
     (yrecur
      (fn [f]
        (let [g (fn [n] ((f f) n))]
          (fn [n]
            (if (< n 2) 1 (* n (g (dec n)))))))))

;; (fact 5) => 120

ycombinator-step5.clj

(ns step5)

(defn yrecur
  [f]
  (f f))

(defn wrap
  [h]
  (yrecur
   (fn [f]
     (let [g (fn [n] ((f f) n))]
       (h g)))))

(def fact
     (wrap
      (fn [g]
        (fn [n]
          (if (< n 2) 1 (* n (g (dec n))))))))

;; (fact 5) => 120

ycombinator-step6.clj

(ns step6)

(defn yrecur
  [f]
  (f f))

(defn wrap
  [h]
  (yrecur
   (fn [f]
     (h (fn [n] ((f f) n))))))

(def fact
     (wrap
      (fn [g]
        (fn [n]
          (if (< n 2) 1 (* n (g (dec n))))))))

;; (fact 5) => 120

ycombinator-step7.clj

(ns step7)

(defn Y
  [h]
  ((fn [f] (f f)) (fn [f]
                    (h (fn [n]
                         ((f f) n))))))

(def fact
     (Y (fn [g]
          (fn [n]
            (if (< n 2) 1 (* n (g (dec n))))))))

;; (fact 5) => 120