Guile implementation of Clojure's `#(...)` reader macro, but using `##(...)` instead to avoid conflicting with vectors.

gistfile1.scm

(use-srfis '(1 69))
(read-hash-extend #\#
  (lambda (c port)
    (define ht (make-hash-table eqv?))
    (define (ht-ref key)
      (hash-table-ref ht key (lambda ()
                               (define sym (gensym))
                               (hash-table-set! ht key sym)
                               sym)))
    (define (hash-key x)
      (case x
        ((% %1) 1)
        ((%2) 2)
        ((%3) 3)
        ((%&) 0)
        ((#{}#) #f)
        (else (and (symbol? x)
                   (symbol-interned? x)
                   (let ((str (symbol->string x)))
                     (and (char=? #\% (string-ref str 0))
                          (char<=? #\1 (string-ref str 1) #\9)
                          (string->number (substring/shared str 1))))))))
    (define (process x)
      (cond ((hash-key x) => ht-ref)
            ((list? x) (map process x))
            (else x)))
    (define body (process (read port)))
    (define max-arg (apply max 0 (hash-table-keys ht)))
    (define lambda-list (list-tabulate max-arg (compose ht-ref 1+)))
    `(lambda (,@lambda-list . ,(hash-table-ref/default ht 0 '()))
       ,body)))