Quick test running for test unit/rspec sans all the other plugins hupla.. current test under cursor, current file, current suite; puts errors in QuickFix. Uses m instead of testrb for test unit line support.

gistfile1.vim

autocmd BufNewFile,BufRead *_test.rb setlocal makeprg=m errorformat=%A%>\ \ %n)\ Failure:,%C%m\ [%f:%l]:,%Z
autocmd BufNewFile,BufRead *_test.rb setlocal makeprg=m errorformat+=%A%>\ \ %n)\ Error:,%C%.%#:,%C%m\ for\ #<%.%#>,%Z\ \ \ \ %f:%l:in\ \`%.%#\',%-G%.%#

"autocmd BufNewFile,BufRead *_spec.rb setlocal makeprg=rspec errorformat=rspec\ %f:%l\ #\ %m,%-G%.%#
autocmd BufNewFile,BufRead *_spec.rb setlocal makeprg=rspec errorformat=%A%>\ \ %n)%.%#,%C%>\ \ \ \ \ Failure/Error:%.%#,%C\ \ \ \ \ %m:,%C\ \ \ \ \ \ \ ,%C\ \ \ \ \ \ \ %m,%C\ \ \ \ \ #\ %f:%l:in%.%#,%Z,%-G%.%#

function! RunMake(...)
  if a:0 == 1
    echo "Running " . &makeprg . " " . a:1 . "..."
    silent exec "make! " . a:1
  elseif a:0 == 2
    echo "Running " . &makeprg . " " . a:1 . " -l " . a:2 . "..."
    silent exec "make! " . a:1 . " -l " . a:2
  else
    echo "Running " . &makeprg . "..."
    silent exec "make!"
  endif
  redraw
  if len(getqflist()) > 0
    cw
    redraw
    call RedBar('')
  else
    ccl
    redraw
    call GreenBar("")
  endif
endfunction

command! TestSuite call RunMake()
command! TestFile call RunMake(expand('%'))
command! TestLine call RunMake(expand('%'), line('.'))

nmap \ts :TestSuite<CR>
nmap \tf :TestFile<CR>
nmap \tl :TestLine<CR>