pkgbuild setbfree-git

PKGBUILD

# Maintainer: speps <speps at aur dot archlinux dot org>

pkgname=setbfree-git
_pkgname=setbfree
pkgver=312.112c781
pkgrel=1
pkgdesc="A DSP Tonewheel Organ emulator."
arch=(i686 x86_64)
url="http://setbfree.org/"
license=('GPL')
conflicts=("$_pkgname")
provides=("$_pkgname")
depends=('jack' 'liblo' 'tk' 'desktop-file-utils')
optdepends=('ttf-bitstream-vera')
makedepends=('lv2')
install="setbfree.install"
source=("$pkgname"::"git://github.com/pantherb/setBfree.git"
        "https://raw.github.com/pantherb/setBfree/master/debian/$_pkgname.desktop")
md5sums=('SKIP'
         '8c2a863562f26856dcff0a456cf36dcf')

pkgver() {
	cd $pkgname
	printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/$pkgname"
  make ENABLE_CONVOLUTION=yes PREFIX=/usr
}

package() {
  cd "$srcdir/$pkgname"
  make clean
  FONTFILE="/usr/share/fonts/TTF/VeraBd.ttf" make ENABLE_CONVOLUTION=yes DESTDIR="$pkgdir/" PREFIX=/usr install

  # desktop file
  install -Dm644 "../$_pkgname.desktop" \
    "$pkgdir/usr/share/applications/$_pkgname.desktop"

  # icon
  install -Dm644 doc/setBfree.png \
    "$pkgdir/usr/share/icons/setBfree.png"

  # man
  install -d "$pkgdir/usr/share/man/man1"
  install -Dm644 doc/*.1 \
    "$pkgdir/usr/share/man/man1"

  # docs
  install -d "$pkgdir/usr/share/doc/$_pkgname"
  install -Dm644 doc/{midi.txt,signal_flow.png} \
    "$pkgdir/usr/share/doc/$_pkgname"
}