gistfile1.sh

# Maintainer:  prettyvanilla <prettyvanilla@posteo.at>
# Contributor: SpepS <dreamspepser at yahoo dot it>

pkgname=ingen-svn
pkgver=0.5.1.r5392
pkgrel=1
pkgdesc="A JACK modular audio processing system using LV2 or LADSPA plugins."
arch=('i686' 'x86_64')
url="http://drobilla.net/software/ingen"
license=('GPL3')
depends=('python' 'lilv-svn' 'ganv-svn' 'suil-svn' 'jack' 'webkitgtk2')
makedepends=('subversion' 'boost' 'raul-svn')
install="${pkgname}.install"
provides=("ingen")
conflicts=("ingen")

_svnname=ingen
source=("svn+http://svn.drobilla.net/lad/trunk/${_svnname}")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_svnname}"
  local rel=`grep "^INGEN_VERSION" wscript | cut -d "'" -f 2`
  local ver="$(svnversion)"
  printf "%s.r%s" "${rel}" "${ver//[[:alpha:]]}"
}

build() {
  cd "${srcdir}/${_svnname}"
  CPPFLAGS='-I/usr/include/serd-0 -I/usr/include/lilv-0 -I/usr/include/sord-0' python waf configure --prefix=/usr
  python waf
}

package() {
  cd "${srcdir}/${_svnname}"
  python waf install --destdir="${pkgdir}"
}