Add SSH URL Handler for macOS

README.md

Dependencies

• SwiftDefaultApps - https://github.com/Lord-Kamina/SwiftDefaultApps
• Platypus - https://sveinbjorn.org/platypus

How to

Use Platypus to create org.codemedic.SSHHandler app, as an ssh URL handler, making use of the applescript below.

Not sure, but I am told to run it once to get the URL handler registered.

open -a org.codemedic.SSHHandler

Now we need to register the app as the default SSH URL handler. For this, make use of swda from SwiftDefaultApps.

./swda setHandler --URL ssh --application org.codemedic.SSHHandler

Thats it!

Now you can try it using open ssh://server.myhost.com from terminal.

script.applescript

#!/usr/bin/osascript

on openURL(theURL)
	set colonIndex to offset of ":" in theURL
	set sshCommand to "ssh " & (text (colonIndex + 3) thru (length of theURL) of theURL)

	tell application id "com.googlecode.iterm2"
		activate
		if not (exists window 1) then
			reopen
		else
			tell current window to create tab with default profile
		end if

		tell current session of current window
			write text sshCommand
		end tell
	end tell
end openURL

-- For this script to behave as a URL handler
on open location theURL
	openURL(theURL)
end open location

-- For testing 
on run argv
	if (count of argv) ≤ 0 then
		openURL("ssh://srv.example.com")
		return
	end if
	
	set theURL to item 1 of argv
	openURL(theURL)
end run