script.txt

title fibonacci
author codlark
verbose_logging

realtime_interval 0.75
========
OBJECTS
========
play
green
.0...
.00..
.000.
.00..
.0...

pause p
yellow
.0.0.
.0.0.
.0.0.
.0.0.
.0.0.

background .
black
00000
00000
00000
00000
00000

1
white
.00..
..0..
..0..
..0..
.000.

2
white
.000.
...0.
.000.
.0...
.000.

3
white
.000.
...0.
.000.
...0.
.000.

4
white
.0.0.
.0.0.
.000.
...0.
...0.

5
white
.000.
.0...
.000.
...0.
.000.

6
white
.000.
.0...
.000.
.0.0.
.000.

7
white
.000.
.0.0.
...0.
..0..
..0..

8
white
.000.
.0.0.
.000.
.0.0.
.000.

9
white
.000.
.0.0.
.000.
...0.
...0.

0
white
.000.
.0.0.
.0.0.
.0.0.
.000.

target (used to find the right number)
transparent

source1
transparent

source2
transparent

temp
transparent

turn1 # (used to mark phase of execution)
white darkgray
..11.
0001.
.0.1.
.0.1.
.0111

turn2 $
white darkgray
..111
000.1
.0111
.01..
.0111

turn3 %
white darkgray
..111
000.1
.0111
.0..1
.0111

turn4 &
white darkgray gray
..1.1
002.1
.0111
.0..1
.0..1

=======
LEGEND
=======

@ = 0 and target
s = 1 and source1
c = 1 and source2
t = 0 and temp

marker = target or source1 or source2 or temp

number = 0 or 1 or 2 or 3 or 4 or 5 or 6 or 7 or 8 or 9

turn = turn1 or turn2 or turn3 or turn4

player = play or pause
=======
SOUNDS
=======

================
COLLISIONLAYERS
================
background
player
marker
turn
number
======
RULES
======

[action play] -> [pause]
[action pause] -> [play]
[moving player] -> [stationary player]

(right[play][turn][][] -> [play][turn][][])

(turn 1, copy source 1 to target)
right[play][turn1][ 0 | 0 | 0 source1 ] -> [play][turn2][ 0 | 0 | 0 source1 ]
right[play][turn1][ number source1 ][ number target ] -> [play][turn1][down number source1 ][up number target ]

(turn 2, copy source 2 to target and temp)
right[play][turn2][ 0 | 0 | 0 source2 ] -> [play][turn3][ 0 | 0 | 0 source2 ]
right[play][turn2][ number source2 ][ number target ][ number temp ] -> [play][turn2][down number source2 ][up number target ][up number temp]

(turn 3, copy temp to source 1)
right[play][turn3][ 0 | 0 | 0 temp ] -> [play][turn4][ 0 | 0 | 0 temp ]
right[play][turn3][ number temp ][ number source1 ] -> [play][turn3][down number temp ][up number source1 ]

(turn 4, copy target to source 2)
right[play][turn4][ 0 | 0 | 0 target ] -> [play][turn1][ 0 | 0 | 0 target ]
right[play][turn4][ number target ][ number source2 ] -> [play][turn4][down number target ][up number source2 ]



(math, up for increment, down for decrement)
startloop
right[ number |down 0] -> [down number | 9]
right[no number |down 0] -> [| 9]
[down 1] -> [0]
[down 2] -> [1]
[down 3] -> [2]
[down 4] -> [3]
[down 5] -> [4]
[down 6] -> [5]
[down 7] -> [6]
[down 8] -> [7]
[down 9] -> [8]
endloop

startloop
[up 0] -> [1]
[up 1] -> [2]
[up 2] -> [3]
[up 3] -> [4]
[up 4] -> [5]
[up 5] -> [6]
[up 6] -> [7]
[up 7] -> [8]
[up 8] -> [9]
right[ number |up 9] -> [up number | 0]
right[no number |up 9] -> [| 0]
endloop

==============
WINCONDITIONS
==============

=======
LEVELS
=======
.p.#.
.....
.00@.
.....
.00s.
.....
.00c.
.....
.00t.
.....