create a call graph

dot.p6

my $test = q:to<END>;
void a();
void a(
      ) {
    b();
    c();
}
END


grammar G {
    token TOP { [ .*? <fun> ]+ .* }
    token nm {  <[a..z_]>+   }
    token fun { ^^ \w \V*?  <nm> '(' <-[)]>*? ')' \s* <fun-block> };
    token end-fun-block { ^^ '}'}
    token fun-block {
      '{'  [
              [  <!before <.end-fun-block> > . ]+?   # skip, not to far
               <called-fun=.nm>  '('

            ]*
            .*?
      <.end-fun-block>
    }
}

sub infix:«->» { "  $^a -> $^b\n" };

class actions {
     method TOP($/) {
         my $s = '';
         for $<fun> {
           my @called =  (grep { $_ ne 'sizeof'| 'memcpy'  },  .<fun-block><called-fun>).unique( :with( &[eq] )) ;
           $s ~= [~] ~.<nm> X[->] @called;
         }
         make "digraph A \{\n$s\}";
    }
}



# say G.parse($test);
say G.parse(slurp("src/rrb.c"), :actions(actions)).ast ;

gistfile1.txt

git clone https://github.com/hyPiRion/c-rrb
cd c-rrb
perl6 dot.p6 > rrb.dot  # dot.p6 must created in c-rrb
dot -Tpdf rrb.dot > rrb.pdf
open rrb.pdf  # on mac