Delaunay to Voronoi

delaunay-to-voronoi.jl

# should run this using Luxor#master or >= v2.20.0 - 
# I replaced a dodgy implementation of Jarvis March with  
# a hopefully less dodgy implementation of Graham Scan.

using Luxor, ColorSchemes

@draw begin
    background("black")
    println("create points")
    verts = randompointarray(BoundingBox(), 30)

    println("triangulate")
    triangles = polytriangulate(verts)

    println("draw the triangulation")
    @layer begin
        for tri in triangles
            randomhue()
            poly(tri, :stroke, close=true)
        end
    end
    
    dict = Dict{Point, Vector{Int}}()
    println("build point -> triangle dictionary")
    for (n, t) in enumerate(triangles)
        for pt in t
            if haskey(dict, pt)
                push!(dict[pt], n)
            else
                dict[pt] = [n]
            end
        end
    end
    
    println("build cells")
    setopacity(0.9)
    setline(3)
    for v in verts
        hull = Point[]
        # vertex v belongs in triangle tri
        tris = dict[v]
        print(" Δ")
        for tri in tris
            push!(hull, trianglecenter(triangles[tri]...))
        end
        sethue(get(ColorSchemes.tableau_colorblind, rand()))
        print("⛵")
        ph = polyhull(hull)
        print("✏")
        poly(ph, :fillpreserve, close=true)
        sethue("black")
        strokepath()
    end
end 500 500

An example made with this code: