mesh logo 1

mesh-logo-1.jl

using Luxor

function meshlogo(fname)
    Drawing(600, 600, fname)
    origin()

    # background
    squircle(O, 285, 285, :clip, rt=0.2)
    sethue("slateblue4")
    paint()

    # build point array
    pts = polysample(box(O, 600, 600, vertices=true), 16)
    for pt in ngon(O, 100, 3, π/6, vertices=true)
        for θ in 0:π/8:6π
            for i in 160:40:265
                push!(pts, pt  + polar(i, θ))
            end
        end
    end

    # make triangulation
    tris = polytriangulate(pts)

    # draw triangles
    setline(.5)
    for tri in tris
        #sethue("white")
        sethue("red")
        poly(tri, :stroke, close=true)
    end

    # clipping for julia circles
    @layer begin
        for pt in ngon(O + (0, 35), 150, 3, π/6, vertices=true)
            circlepath(pt, 110, :path)
        end
        sethue("white")
        setline(3)
        strokepreserve()
        clip()
        setline(1)
        for tri in tris
            sethue([Luxor.julia_red, Luxor.julia_green, Luxor.julia_purple][rand(1:end)])
            poly(tri, :fillpreserve, close=true)
            sethue("white")
            strokepath()
        end
        sethue("white")
        circle.(pts, 3, :fill)
        clipreset()
    end

    # draw nodes
    sethue("white")
    circle.(pts, 3, :fill)

    #outline
    setline(4)
    sethue("red")
    squircle(O, 285, 285, :stroke, rt=0.2)

    finish()
    preview()
end

meshlogo("/tmp/meshlogo.png")