Example XTDB queries with tag inclusions and exclusions

xtdb-inclusions-exclusions

(ns scratch
  (:require [xtdb.api :as xt])
  (:import (java.util UUID)))

(def node (xt/start-node {}))

(defn- put-articles []
  (for [lev ["intro" "intermediate" "advanced"]
        lan ["java" "clojure" "python"]
        :let [url     (str "http://foo.bar/" lev "-" lan)
              article {:xt/id        (UUID/randomUUID)
                       :article/url  url
                       :article/tags [lev lan]}]]
    (xt/submit-tx node [[::xt/put article]])))

(defn query-with-in [inclusions exclusions]
  (let [query {:find     '[(pull ?article [*])]
               :where    '[[?article :article/url]
                           [?article :article/tags in-tags]
                           (not [?article :article/tags out-tags])]
               :in       '[[in-tags ...] [out-tags ...]]}]
    (xt/q (xt/db node) query inclusions exclusions)))

(defn query-manually [inclusions exclusions]
  (let [query {:find     '[(pull ?article [*])]
               :where    '[[?article :article/url]
                           [?article :article/tags in-tags]]
               :in       '[[in-tags ...]]}
        query (update query :where into (mapv #(cons 'not [['?article :article/tags %]]) exclusions))]
    (xt/q (xt/db node) query inclusions)))

(comment
  (put-articles)
  (query-with-in ["java" "python"] ["intro" "advanced"])
  (query-manually ["java" "python"] ["intro" "advanced"]))

Simple example of the include/exclude logic I'm trying to implement.

The query-with-in fn is how I'd like to write it; the query-manually fn gives the behavior I expect.