Spock Mocks Cheatsheet

args-in-return.groovy

def 'use method arguments in return value'() {
    given:
    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    1 * userService.createUser(email, name) >> { String e, String n -> 
        new User(email: e, name: n)
    }
    1 * userService.sendWelcomeEmail(_ as User)
}

build.gradle

dependencies {
    compile 'org.codehaus.groovy:groovy-all:2.1.3'
    testCompile 'org.spockframework:spock-core:0.7-groovy-2.0'
    
    testCompile 'cglib:cglib-nodep:2.2'       // For mocking classes
    testCompile 'org.objenesis:objenesis:1.2' // For mocking final classes
}

class-match.groovy

    then:
    1 * userService.createUser(_ as String, _ as String) >> user
    1 * userService.sendWelcomeEmail(user)

closure-match.groovy

def 'closure-based argument matching'() {
    given:
    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    1 * userService.createUser(email, name) >> new User(email: email, name: name)
    1 * userService.sendWelcomeEmail({ User u -> u.email == email && u.name == name })
}

exact-match.groovy

def 'exact argument matching'() {
    given:
    User user = new User()

    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    1 * userService.createUser(email, name) >> user
    1 * userService.sendWelcomeEmail(user)
}

mock-call-order-fail.groovy

@FailsWith(WrongInvocationOrderError)
def 'verify mock method call order - fail'() {
    given:
    User user = new User()

    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    1 * userService.sendWelcomeEmail(user)

    then:
    1 * userService.createUser(email, name) >> user
}

mock-call-order-pass.groovy

def 'verify mock method call order - pass'() {
    given:
    User user = new User()

    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    1 * userService.createUser(email, name) >> user

    then:
    1 * userService.sendWelcomeEmail(user)
}

mock-outside-of-spec.groovy

def 'mock definition outside of test spec'() {
    given:
    String email = "test@email.com"
    String name = "John Doe"

    when:
    userController.createUser(email, name)

    then:
    interaction {
        userCreationMocks(email, name)
    }
}

private void userCreationMocks(String email, String name) {
    User user = new User()

    1 * userService.createUser(email, name) >> user
    1 * userService.sendWelcomeEmail(user)
}

mock-setup-def.groovy

def userService = Mock(UserService)

mock-setup.groovy

UserController userController

UserService userService

def setup() {
    userService = Mock()

    userController = new UserController(
            userService: userService
    )
}

no-other-mocks-called.groovy

    then:
    1 * userService.createUser(email, name) >> user
    1 * userService.sendWelcomeEmail(user)
    0 * _

wildcard-match.groovy

def 'wildcard-based method argument matching'() {
    given:
    User user = new User()

    when:
    userController.createUser("test@email.com", "John Doe")

    then:
    1 * userService.createUser(_, _) >> user
    1 * userService.sendWelcomeEmail(user)
}