A Groovy script that takes a CSV filePath (string), and turns it into a List of Maps (via groovycsv lib).

csv2List.groovy

@Grab('com.xlson.groovycsv:groovycsv:1.0')
import com.xlson.groovycsv.CsvParser

// a normally parsed csv can only be searched through ONCE
// this is used to create a "re-searchable" object (List of Maps)
List<Map> csv2List( String filePath, boolean shouldTrim = true, String charset = 'UTF-8' ) {
    new File( filePath ).withReader(charset) { r ->
        new CsvParser().parse( r ).with { csv ->
            return csv.collect { line ->
                line.columns.collectEntries { c, v ->
                    [ c, (shouldTrim ? line[ c ].trim() : line[ c ]) ]
                }
            }
        }
    }
}

Careful to close the reader, how about:

List<Map> csv2List( String filePath ) {
    new File( filePath ).withReader { r ->
        new CsvParser().parse( r ).with { csv ->
            csv.collect { line ->
                line.columns.collectEntries { c, v ->
                    [ c, line[ c ].trim() ]
                }
            }
        }
    }
}

Holy cow, that's great! Thanks @timyates! Didn't even know about collectEntries - groovy :)

Added optional trimming to boot.

      new CsvParser().parse(r).with { csv ->
                csv.collect { PropertyMapper line ->
                    line.toMap()
                }
            }