convert MySQL dump to CSV

mysqldump2csv.pl

#!/usr/bin/env perl
use 5.010;
use strict;
use warnings;

my $schema;
my $table;
while (my $line = <>) {
    my @csv = ();
    if ($line =~ m{^ CREATE \s+ TABLE \s+ `(?<table> \w+)`}ox) {
        $table = $+{table};
        $schema = [];
    } elsif ($schema && $line =~ m{^ \s* `(?<col> \w+)` }ox) {
        push @$schema, $+{col};
    } elsif ($line =~ m{
        (?(DEFINE)
            (?<num> -? [0-9]+ (?: \. [0-9]+ )? )
            (?<str> '(?: [^'\\] | \\. ) *' )
            (?<nul> NULL )
            (?<val> (?&num) | (?&str) | (?&nul) )
            (?<rec> \( ( (?&val) (?: , (?&val) ) * ) \) (?{ push @csv, $^N }) )
        )
        ^
        INSERT \s+ INTO \s+ `(?<table> \w+)` \s+ VALUES \s+
        (?&rec) (?: , (?&rec) ) *
        ; $
    }ox) {
        my $fh;
        my $file = $table . '.csv';
        if ($schema) {
            open($fh, '>:raw', $file) || die "can't create $file: $!";
            say $fh join(',', @$schema);
        } else {
            open($fh, '>>:raw', $file) || die "can't update $file: $!";
        }
        $schema = undef;
        say $fh $_ for @csv;
        close $fh;
    } else {
        next;
    }
}