Create a gist now

Instantly share code, notes, and snippets.

Embed
What would you like to do?
im@sparql_Examples
PREFIX schema: <http://schema.org/>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT ?o ?h
WHERE {
?s schema:name|schema:alternateName ?o;
schema:height ?h.
}order by(?h)
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT ?ユニット名 (group_concat(?名前;separator=", ")as ?メンバー)
WHERE {
?s rdf:type imas:Unit;
schema:name ?ユニット名;
schema:member ?m.
?m schema:name ?名前.
}group by (?ユニット名) order by(?ユニット名)
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT ?ユニット名 (avg(?h) as ?平均身長)
WHERE {
?s rdf:type imas:Unit;
schema:name ?ユニット名;
schema:member ?m.
?m schema:height ?h.
}group by(?ユニット名) order by desc(?平均身長)
PREFIX schema: <http://schema.org/>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
select ?利き手 ?名前
where{
?s schema:name|schema:alternateName ?name;
imas:Handedness ?利き手;
filter(regex(str(?name), "まゆ")).
?idol imas:Handedness ?利き手;
schema:name ?名前.
}
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT (count(?name)as ?回数) (sample(?name)as ?楽曲名)
WHERE {
?s rdf:type imas:SetlistNumer;
schema:name ?name;
}group by ?name having(?回数>4) order by ?回数
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT *
WHERE {
?s rdf:type imas:ScriptText;
imas:Source ?source;
schema:text ?text.
?source schema:name ?name;
filter(regex(str(?name),"千早"))
}order by ?text
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
PREFIX schema: <http://schema.org/>
SELECT (SUM(?得票数) as ?総得票数) (Sample(?nm) as ?名前)
WHERE {
?s schema:member ?o;
imas:VoteNumber ?得票数.
?o schema:name ?nm
}group by(?o) order by(?総得票数)
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT ?calling ?called
WHERE {
?s rdf:type imas:CallName;
imas:Source ?caller;
imas:Destination ?callee;
imas:Called ?called.
?caller schema:name ?name1.
?callee schema:name ?name2.
bind(concat(?name1,"",?name2)as ?calling)
}order by rand()
PREFIX schema: <http://schema.org/>
PREFIX math: <http://www.w3.org/2005/xpath-functions/math#>
SELECT ?名前 (?height as ?身長) (?weight as ?体重) ?デュポア式 ?新谷式 ?藤本式
WHERE {
?s schema:name ?名前;
schema:height ?height;
schema:weight ?weight;
bind(math:pow(?height,0.725)*math:pow(?weight,0.425)*0.007184 as ?デュポア式)
bind(math:pow(?height,0.725)*math:pow(?weight,0.425)*0.007358 as ?新谷式)
bind(math:pow(?height,0.663)*math:pow(?weight,0.444)*0.008883 as ?藤本式)
}order by ?デュポア式
PREFIX imas: <https://sparql.crssnky.xyz/imasrdf/URIs/imas-schema.ttl#>
SELECT distinct ?ss ?cv
WHERE {
?s imas:cv ?cv.
service <http://ja.dbpedia.org/sparql>{
?ss ?a ?cv.
bind(concat("http://ja.dbpedia.org/resource/",str(?cv))as ?cvs)
filter(str(?ss)=?cvs)
}
}order by ?cv
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment