Created
October 18, 2018 06:22
-
-
Save cwhinfrey/bc3b46b63dcf342142059b6b2c3a6c5a to your computer and use it in GitHub Desktop.
ERC721 with updated _clearApproval
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.24; | |
import "./IERC721.sol"; | |
import "./IERC721Receiver.sol"; | |
import "../../math/SafeMath.sol"; | |
import "../../utils/Address.sol"; | |
import "../../introspection/ERC165.sol"; | |
/** | |
* @title ERC721 Non-Fungible Token Standard basic implementation | |
* @dev see https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract ERC721 is ERC165, IERC721 { | |
using SafeMath for uint256; | |
using Address for address; | |
// Equals to `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))` | |
// which can be also obtained as `IERC721Receiver(0).onERC721Received.selector` | |
bytes4 private constant _ERC721_RECEIVED = 0x150b7a02; | |
// Mapping from token ID to owner | |
mapping (uint256 => address) private _tokenOwner; | |
// Mapping from token ID to approved address | |
mapping (uint256 => address) private _tokenApprovals; | |
// Mapping from owner to number of owned token | |
mapping (address => uint256) private _ownedTokensCount; | |
// Mapping from owner to operator approvals | |
mapping (address => mapping (address => bool)) private _operatorApprovals; | |
bytes4 private constant _InterfaceId_ERC721 = 0x80ac58cd; | |
/* | |
* 0x80ac58cd === | |
* bytes4(keccak256('balanceOf(address)')) ^ | |
* bytes4(keccak256('ownerOf(uint256)')) ^ | |
* bytes4(keccak256('approve(address,uint256)')) ^ | |
* bytes4(keccak256('getApproved(uint256)')) ^ | |
* bytes4(keccak256('setApprovalForAll(address,bool)')) ^ | |
* bytes4(keccak256('isApprovedForAll(address,address)')) ^ | |
* bytes4(keccak256('transferFrom(address,address,uint256)')) ^ | |
* bytes4(keccak256('safeTransferFrom(address,address,uint256)')) ^ | |
* bytes4(keccak256('safeTransferFrom(address,address,uint256,bytes)')) | |
*/ | |
constructor() | |
public | |
{ | |
// register the supported interfaces to conform to ERC721 via ERC165 | |
_registerInterface(_InterfaceId_ERC721); | |
} | |
/** | |
* @dev Gets the balance of the specified address | |
* @param owner address to query the balance of | |
* @return uint256 representing the amount owned by the passed address | |
*/ | |
function balanceOf(address owner) public view returns (uint256) { | |
require(owner != address(0)); | |
return _ownedTokensCount[owner]; | |
} | |
/** | |
* @dev Gets the owner of the specified token ID | |
* @param tokenId uint256 ID of the token to query the owner of | |
* @return owner address currently marked as the owner of the given token ID | |
*/ | |
function ownerOf(uint256 tokenId) public view returns (address) { | |
address owner = _tokenOwner[tokenId]; | |
require(owner != address(0)); | |
return owner; | |
} | |
/** | |
* @dev Approves another address to transfer the given token ID | |
* The zero address indicates there is no approved address. | |
* There can only be one approved address per token at a given time. | |
* Can only be called by the token owner or an approved operator. | |
* @param to address to be approved for the given token ID | |
* @param tokenId uint256 ID of the token to be approved | |
*/ | |
function approve(address to, uint256 tokenId) public { | |
address owner = ownerOf(tokenId); | |
require(to != owner); | |
require(msg.sender == owner || isApprovedForAll(owner, msg.sender)); | |
_tokenApprovals[tokenId] = to; | |
emit Approval(owner, to, tokenId); | |
} | |
/** | |
* @dev Gets the approved address for a token ID, or zero if no address set | |
* Reverts if the token ID does not exist. | |
* @param tokenId uint256 ID of the token to query the approval of | |
* @return address currently approved for the given token ID | |
*/ | |
function getApproved(uint256 tokenId) public view returns (address) { | |
require(_exists(tokenId)); | |
return _tokenApprovals[tokenId]; | |
} | |
/** | |
* @dev Sets or unsets the approval of a given operator | |
* An operator is allowed to transfer all tokens of the sender on their behalf | |
* @param to operator address to set the approval | |
* @param approved representing the status of the approval to be set | |
*/ | |
function setApprovalForAll(address to, bool approved) public { | |
require(to != msg.sender); | |
_operatorApprovals[msg.sender][to] = approved; | |
emit ApprovalForAll(msg.sender, to, approved); | |
} | |
/** | |
* @dev Tells whether an operator is approved by a given owner | |
* @param owner owner address which you want to query the approval of | |
* @param operator operator address which you want to query the approval of | |
* @return bool whether the given operator is approved by the given owner | |
*/ | |
function isApprovedForAll( | |
address owner, | |
address operator | |
) | |
public | |
view | |
returns (bool) | |
{ | |
return _operatorApprovals[owner][operator]; | |
} | |
/** | |
* @dev Transfers the ownership of a given token ID to another address | |
* Usage of this method is discouraged, use `safeTransferFrom` whenever possible | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function transferFrom( | |
address from, | |
address to, | |
uint256 tokenId | |
) | |
public | |
{ | |
require(_isApprovedOrOwner(msg.sender, tokenId)); | |
require(to != address(0)); | |
_removeTokenFrom(from, tokenId); | |
_addTokenTo(to, tokenId); | |
emit Transfer(from, to, tokenId); | |
} | |
/** | |
* @dev Safely transfers the ownership of a given token ID to another address | |
* If the target address is a contract, it must implement `onERC721Received`, | |
* which is called upon a safe transfer, and return the magic value | |
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise, | |
* the transfer is reverted. | |
* | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function safeTransferFrom( | |
address from, | |
address to, | |
uint256 tokenId | |
) | |
public | |
{ | |
// solium-disable-next-line arg-overflow | |
safeTransferFrom(from, to, tokenId, ""); | |
} | |
/** | |
* @dev Safely transfers the ownership of a given token ID to another address | |
* If the target address is a contract, it must implement `onERC721Received`, | |
* which is called upon a safe transfer, and return the magic value | |
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise, | |
* the transfer is reverted. | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
* @param _data bytes data to send along with a safe transfer check | |
*/ | |
function safeTransferFrom( | |
address from, | |
address to, | |
uint256 tokenId, | |
bytes _data | |
) | |
public | |
{ | |
transferFrom(from, to, tokenId); | |
// solium-disable-next-line arg-overflow | |
require(_checkAndCallSafeTransfer(from, to, tokenId, _data)); | |
} | |
/** | |
* @dev Returns whether the specified token exists | |
* @param tokenId uint256 ID of the token to query the existence of | |
* @return whether the token exists | |
*/ | |
function _exists(uint256 tokenId) internal view returns (bool) { | |
address owner = _tokenOwner[tokenId]; | |
return owner != address(0); | |
} | |
/** | |
* @dev Returns whether the given spender can transfer a given token ID | |
* @param spender address of the spender to query | |
* @param tokenId uint256 ID of the token to be transferred | |
* @return bool whether the msg.sender is approved for the given token ID, | |
* is an operator of the owner, or is the owner of the token | |
*/ | |
function _isApprovedOrOwner( | |
address spender, | |
uint256 tokenId | |
) | |
internal | |
view | |
returns (bool) | |
{ | |
address owner = ownerOf(tokenId); | |
// Disable solium check because of | |
// https://github.com/duaraghav8/Solium/issues/175 | |
// solium-disable-next-line operator-whitespace | |
return ( | |
spender == owner || | |
getApproved(tokenId) == spender || | |
isApprovedForAll(owner, spender) | |
); | |
} | |
/** | |
* @dev Internal function to mint a new token | |
* Reverts if the given token ID already exists | |
* @param to The address that will own the minted token | |
* @param tokenId uint256 ID of the token to be minted by the msg.sender | |
*/ | |
function _mint(address to, uint256 tokenId) internal { | |
require(to != address(0)); | |
_addTokenTo(to, tokenId); | |
emit Transfer(address(0), to, tokenId); | |
} | |
/** | |
* @dev Internal function to burn a specific token | |
* Reverts if the token does not exist | |
* @param tokenId uint256 ID of the token being burned by the msg.sender | |
*/ | |
function _burn(address owner, uint256 tokenId) internal { | |
_removeTokenFrom(owner, tokenId); | |
emit Transfer(owner, address(0), tokenId); | |
} | |
/** | |
* @dev Internal function to clear current approval of a given token ID | |
* and emit an Approval event | |
* Reverts if the given address is not indeed the owner of the token | |
* @param owner owner of the token | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function _clearApproval(address owner, uint256 tokenId) internal { | |
emit Approval(owner, address(0), tokenId); | |
_clearApprovalState(owner, tokenId); | |
} | |
/** | |
* @dev Private function to clear current approval of a given token ID | |
* Reverts if the given address is not indeed the owner of the token | |
* @param owner owner of the token | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function _clearApprovalState(address owner, uint256 tokenId) private { | |
require(ownerOf(tokenId) == owner); | |
if (_tokenApprovals[tokenId] != address(0)) { | |
_tokenApprovals[tokenId] = address(0); | |
} | |
} | |
/** | |
* @dev Internal function to add a token ID to the list of a given address | |
* @param to address representing the new owner of the given token ID | |
* @param tokenId uint256 ID of the token to be added to the tokens list of the given address | |
*/ | |
function _addTokenTo(address to, uint256 tokenId) internal { | |
require(_tokenOwner[tokenId] == address(0)); | |
_tokenOwner[tokenId] = to; | |
_ownedTokensCount[to] = _ownedTokensCount[to].add(1); | |
} | |
/** | |
* @dev Internal function to remove a token ID from the list of a given address | |
* @param from address representing the previous owner of the given token ID | |
* @param tokenId uint256 ID of the token to be removed from the tokens list of the given address | |
*/ | |
function _removeTokenFrom(address from, uint256 tokenId) internal { | |
require(ownerOf(tokenId) == from); | |
_clearApprovalState(from, tokenId); | |
_ownedTokensCount[from] = _ownedTokensCount[from].sub(1); | |
_tokenOwner[tokenId] = address(0); | |
} | |
/** | |
* @dev Internal function to invoke `onERC721Received` on a target address | |
* The call is not executed if the target address is not a contract | |
* @param from address representing the previous owner of the given token ID | |
* @param to target address that will receive the tokens | |
* @param tokenId uint256 ID of the token to be transferred | |
* @param _data bytes optional data to send along with the call | |
* @return whether the call correctly returned the expected magic value | |
*/ | |
function _checkAndCallSafeTransfer( | |
address from, | |
address to, | |
uint256 tokenId, | |
bytes _data | |
) | |
internal | |
returns (bool) | |
{ | |
if (!to.isContract()) { | |
return true; | |
} | |
bytes4 retval = IERC721Receiver(to).onERC721Received( | |
msg.sender, from, tokenId, _data); | |
return (retval == _ERC721_RECEIVED); | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment