Decode russian words entered in wrong layout

ruslat.pl

#!/usr/bin/perl

# If you use `xbindkeys` + `xsel`, here's how to make use of this script
# (it should be chmod +x and in your path, obviously)
#
#     "xsel -o | ruslat.pl | xsel -i"
#          Mod4 + q
#
# This maps the Super key (aka Win) + Q to this script and transcodes
# text in the clipboard
# So if you start typing in wrong kb layout,
# select the text you just entered and press Super+Q
# and paste the text with russian keys replaced with latin and vice-versa.

use strict;
use warnings;
use utf8;
binmode STDIN, ":utf8";
binmode STDOUT, ":utf8";

# letters and signs are separated so that we can UC them
# then I wash my keyb left to right, in English and Russian layout, respectively
my $lat   = 'qwertyuiop'.'asdfghjkl'.'zxcvbnm';
my $lat_p = '@#$%^&*_+'.'`[]\\;\',./'.'~{}|:"<>?';
my $rus   = 'йцукенгшщз'.'фывапролд'.'ячсмить';
my $rus_p = '"№;%:?*_+'.'ёхъ\\жэбю.' .'ЁХЪ/ЖЭБЮ,';

$lat .= $lat_p. uc $lat;
$rus .= $rus_p. uc $rus;

# yep, this is what `perldoc perlop` suggests
eval "sub conv { /[а-яё]/i ? y($rus)($lat) : y($lat)($rus) for \@_; \@_; }";
die $@ if $@;

while (<>) {
	print join "", conv(split /(\s+)/, $_);
};