Fallout New Vegas Menu

launch.bat

@ECHO OFF

start "Fallout New Vegas Menu" cmd /c launch_menu.bat

launch_menu.bat

@ECHO OFF
TITLE Fallout New Vegas Menu
CLS

:MENU
CLS

ECHO.
ECHO   ======= FALLOUT NEW VEGAS MENU =======
ECHO.
ECHO     1.  Start with NVSE (default)
ECHO     2.  Start launcher
ECHO     3.  Start directly
ECHO.
ECHO     4.  Autosort mods with BOSS
ECHO.
ECHO     Q.  Exit
ECHO.
ECHO   ======================================
ECHO.

SET INPUT=
SET /P "INPUT=  Select an option [1]: "

IF /I '%INPUT%'==''  GOTO StartNVSE
IF /I '%INPUT%'=='1' GOTO StartNVSE
IF /I '%INPUT%'=='2' GOTO StartFalloutLauncher
IF /I '%INPUT%'=='3' GOTO StartFalloutNV
IF /I '%INPUT%'=='4' GOTO RunBOSS
IF /I '%INPUT%'=='Q' GOTO Quit

CLS
GOTO MENU

:StartNVSE
CLS
ECHO.
ECHO   ^>^> Starting NVSE Loader
START "" nvse_loader.exe
EXIT

:StartFalloutLauncher
CLS
ECHO.
ECHO   ^>^> Starting Fallout Launcher
START "" FalloutNVLauncher.exe
GOTO MENU

:StartFalloutNV
CLS
ECHO.
ECHO   ^>^> Starting Fallout New Vegas
START "" FalloutNV.exe
EXIT

:RunBOSS
CLS
ECHO.
ECHO   ^>^> Running BOSS
boss.exe --update --silent --game FalloutNV
ECHO Completed!
ECHO.
PAUSE
GOTO MENU

:Quit
EXIT