Google Apps Login for Salesforce

GACentric_Google_RegHandler.apex

global class GACentric_Google_RegHandler implements Auth.RegistrationHandler{
        
    global User createUser(Id portalId, Auth.UserData data){
    
        List<User> users = [SELECT Id, username, email FROM User WHERE email = :data.email];
        
        if (users.size() == 0) {
            return null;
        }
     
        if (users.size() == 1) {
            return users[0];
        }

        for (User u : users) {
            // Find the user with username also matching incoming email address as a preference
            if (u.username == data.email) {
                return u;
            }
        }
        // Just return the first since no username match found
        return users[0];
        
    }
    
    global void updateUser(Id userId, Id portalId, Auth.UserData data){
        User u = new User(id=userId);
        u.email = data.email;
        u.lastName = data.lastName;
        u.firstName = data.firstName;
        update(u);
    }
}