Grails Service Transaction Support Methods (Burt Beckwith Grails Book)

gistfile1.groovy

import org.springframework.transaction.interceptor.TransactionAspectSupport
import org.springframework.transaction.support.TransactionSynchronizationManager

class BootStrap {

    def grailsApplication

    def init = { servletContext ->

        // transaction support for services
        for( sc in grailsApplication.serviceClasses ){
            def metaClass = sc.clazz.metaClass

            // proxy method support
            metaClass.getMyProxy = { ->
                grailsApplication.mainContext.getBean(sc.propertyName)
            }

            // returns TransactionStatus
            metaClass.getCurrentTransactionStatus = { ->
                if( !delegate.isTransactionActive() ) {
                    return null
                }
                TransactionAspectSupport.currentTransactionStatus()
            }

            // void, throws NoTransactionException
            metaClass.setRollbackOnly = { ->
                TransactionAspectSupport.currentTransactionStatus().setRollbackOnly()
            }

            // returns boolean
            metaClass.isRollbackOnly = { ->
                if( !delegate.isTransactionActive() ){
                    return false
                }
                delegate.getCurrentTransactionStatus().isRollbackOnly()
            }

            // return boolean
            metaClass.isTransactionActive = { ->
                TransactionSynchronizationManager.isSynchronizationActive()
            }

        }

    }

    def destroy = {

    }

}