Concurrent Programming in Erlang - The University of Kent - chapter 1.8

mailbox.erl

-module(mailbox).

-export([handle_unordered/0, handle_ordered/1, run/0]).

%% Handle messages in the order that they arrive
handle_unordered() -> 
    receive
        stop ->
            ok;
        {_, Message} ->
            io:format("Received message: ~s~n", [Message]),
            handle_unordered()
    end.

%% Handle messages in the order that is passed as argument
handle_ordered(Order) ->
    case Order of
        [] -> ok;
        [Next | Rest] ->
            receive
                stop ->
                    ok;
                {Next, Message} ->
                    io:format("Received message: ~s~n", [Message]),
                    handle_ordered(Rest)
            end
    end.

send_messages(Pid) ->
    Pid ! {third, "The 3rd message"},
    Pid ! {fourth, "The 4th message"},
    Pid ! {first, "The 1st message"},
    Pid ! {second, "The 2nd message"},
    timer:sleep(500),
    Pid ! stop.

run() ->
    io:format("Running unordered~n"),
    UnorderedPid = spawn(mailbox, handle_unordered, []),
    send_messages(UnorderedPid),
    io:format("Running ordered~n"),
    OrderedPid = spawn(mailbox, handle_ordered, [[first, second, third, fourth]]),
    send_messages(OrderedPid).