(autohotkey) - vlc hotkeys remapped to match youtube's hotkeys

youtube hotkeys for vlc.ahk

#ifWinActive ahk_class QWidget ; vlc


k::send {space}         ; play/pause

~LButton::              ; click video to play/pause
keyWait, LButton
keyWait, LButton, D T.2
if (errorLevel)
    {
    mouseGetPos, , , , class_under_mouse
    if class_under_mouse contains video output, video main
        send {space}
    }
return

SC034::send {e}         ; frame by frame  (SC034 = period key)

up::send ^{up}          ; volume up 5%
down::send ^{down}      ; volume down 5%

+,::send {[}            ; decrease speed
+SC034::send {]}        ; increase speed

j::send !{left}         ; jump 10 seconds back 
l::send !{right}        ; jump 10 seconds forwards 



; other non-youtube commands

+j::send +{left}        ; jump 3 seconds back
+l::send +{right}       ; jump 3 seconds back

^+j::send ^{left}       ; jump 1 minute back 
^+l::send ^{right}      ; jump 1 minute forwards 


left::send {p}          ; play previous video
right::send {n}         ; play next video

^f::                    ; resize window to 870x640
winMove, ahk_class QWidget, , , , 870, 640
return


#ifWinActive

hotkeys for vlc that match youtube's hotkeys:

hotkey	action
k	play/pause
left mouse click	play/pause
.	frame by frame
up	volume up
down	volume down
shift + ,	decrease speed
shift + .	increase speed
j	jump 10 second back
l   (the L key)	jump 10 second forwards

 

other non-youtube commands:

hotkey	action
shift + j	jump 3 second back
shift + l	jump 3 second forward
ctrl shift + j	jump 1 minute back
ctrl shift + l	jump 1 minute forward
left	play previous video
right	play next video
ctrl + f	resize window to 870x640