Setting up an angular controller (or $scope) test in coffeescript using jasmine-given (you'll need angular-mocks.js for "inject" and "module" to be available to your specs)

sidebar_controller.coffee

app.controller 'SidebarController', ($scope, SidebarPanels) ->
  $scope.currentPanel = ''

  $scope.panels = SidebarPanels

  $scope.setCurrentPanel = (panel) ->
    $scope.currentPanel = panel.class

  $scope.isCurrentPanel = (panel) ->
    $scope.currentPanel is panel.class

sidebar_controller_spec.coffee

describe "SidebarController", ->

  Given -> module('app')

  Given ->
    inject ($controller, $rootScope, SidebarPanels) =>
      @scope = $rootScope.$new()
      $controller('SidebarController', {$scope: @scope, SidebarPanels: SidebarPanels})

  Given -> @panel = {class: 'bar'}

  describe "setting the current panel", ->
    When  -> @scope.setCurrentPanel(@panel)
    Then  -> expect(@scope.currentPanel).toBe(@panel.class)

  describe "checking if a panel is the current panel", ->

    context "when the currentPanel is set", ->
      Given -> @scope.currentPanel = @panel.class
      Then  -> expect(@scope.isCurrentPanel(@panel)).toBe(true)

    context "when the currentPanel is not set", ->
      Given -> @scope.currentPanel = ''
      Then  -> expect(@scope.isCurrentPanel(@panel)).toBe(false)