KeyboardToBluetooth.pde

import processing.serial.*;

// create object from Serial class
Serial btPort;
boolean[] keyDown = new boolean[100];
int initalSpeed = 30;
int speed = initalSpeed;

void setup()
{
  String portName = Serial.list()[0]; // change the 0 to a 1, 2, 3, etc. to match your port
  btPort = new Serial(this, portName, 9600);
  
  // set background to black, for debugging purposes
  background(0);
}

void draw()
{
}

void keyPressed()
{
  if (key == CODED)
  {
    keyDown[keyCode] = true;
  }
  
  sendBluetooth();
}

void keyReleased()
{
  if (key == CODED)
  {
    keyDown[keyCode] = false;
  }
  
  sendBluetooth();
}

void sendBluetooth()
{
  if (speed < 80)
  {
    speed += 5;
  }
  
  if (keyDown[UP] == true)
  {
    // haut + gauche : on ralentit la roue gauche
    if (keyDown[LEFT] == true) { btPort.write(100 + speed / 2); }
    else {                       btPort.write(100 + speed); }
    
    // haut + droite : on ralentit la roue droite
    if (keyDown[RIGHT] == true) { btPort.write(100 + speed / 2); }
    else {                        btPort.write(100 + speed); }
  }
  else if (keyDown[DOWN] == true)
  {
    // bas + gauche : on ralentit la roue gauche
    if (keyDown[LEFT] == true) { btPort.write(100 - speed / 2); }
    else {                       btPort.write(100 - speed); }
    
    // bas + droite : on ralentit la roue droite
    if (keyDown[RIGHT] == true) { btPort.write(100 - speed / 2); }
    else {                        btPort.write(100 - speed); }
  }
  else if (keyDown[LEFT] == true)
  {
    // seulement gauche : on tourne dans le sens contraire des aiguilles d'une montre
    btPort.write(100 - speed / 2);
    btPort.write(100 + speed / 2);
  }
  else if (keyDown[RIGHT] == true)
  {
    // seulement droite : on tourne dans le sens des aiguilles d'une montre
    btPort.write(100 + speed / 2);
    btPort.write(100 - speed / 2);
  }
  else
  {
    // pas de touche appuyee : on s'arrete
    btPort.write(100);
    btPort.write(100);
    speed = initalSpeed;
  }
  
  btPort.write(0);
}