test

route.coffee

survey = require __dirname + "/../models/survey"

## survey routes
exports.all = (req, res) ->
  survey.all (err, surveys) ->
    res.render "index", surveys: surveys or []

exports.survey_get = (req, res) ->
  id = req.params.id
  survey.one id, (err, survey) ->
    if err or survey.length isnt 1
      res.render "404"
    else
      res.render "survey", survey: survey[0]

exports.survey_post = (req, res) ->
  id = req.params.id
  ip = req.ip
  answer = req.body?.answer

  if ip? and id? and answer?
    survey.ip_exists id, ip, (err, exists) ->
      if exists
        res.json errors: ["you have already submited"]
      else
        survey.add_answer id, answer, ip, (err) ->
          res.json errors: if err then ["something bad happend"] else null
  else
    res.json errors: ["something missing"], result: false

##admin routes
exports.admin_get = (req, res) -> res.render "admin"

exports.admin_post = (req, res) ->
  user     = req.body.user
  password = req.body.password
  survey.user user, (err, user) ->
    if err
      res.json errors: ["something bad happend"], okay: false
    else if user.length isnt 1
      res.json errors: ["user dosn't exist"], okay: false 
    else if user[0].password is password
      req.session.user = user
      res.json errors: null, okay: true
    else
      res.json errors: ["password is incorrect"], okay: false 

exports.logout = (req, res) ->
  req.session.destroy ->
    res.redirect "/"