a-semismooth.ipynb

buchstab.jl

using DifferentialEquations, ArgParse

function buchstab_model(dω,ω,h,p,u)
    dω[1] = ( h(p, u-1)[1] - ω[1] ) / u
end

function buchstabtab(up, res=1, prec=40)
    setprecision(prec) do
        buchstab_history(p, u) = 1/u
        buchstab_initial = [1/BigFloat(2)]
        buchstab_problem = DDEProblem(buchstab_model, buchstab_initial, buchstab_history,
                                      (BigFloat(2), BigFloat(up)+3); constant_lags=[1])
        alg = MethodOfSteps(Tsit5())
        buchstab = solve(buchstab_problem, alg)
        return [(x, buchstab(x)[1]) for x in (BigFloat(2):BigFloat(res):BigFloat(up))]
    end
end

s = ArgParseSettings()
@add_arg_table s begin
    "--resolution", "-r"
        help = "Evaluate at points spaced by this resolution"
        arg_type = BigFloat
        default = 1/BigFloat(10)
    "--precision", "-p"
        help = "Use this much floating point precision"
        arg_type = Int
        default = 40
    "bound"
        help = "Evaluate up to bound"
        arg_type = Int
        required = true
end

args = parse_args(ARGS, s)
prec = args["precision"]
table = buchstabtab(args["bound"], args["resolution"], prec)
for (x,bx) in table
    print(x, "\t", bx, "\n")
end

buchstab.tsv