PKGBUILD

# Maintainer: Davide Depau <davide@depau.eu>
# Contributor: Ivan Shapovalov <intelfx@intelfx.name>
# Contributor: Sven Greiner <sven@sammyshp.de>
# Contributor: vldmr <vldmr@lavabit.com>
# Contributor: Thomas Krug <phragment@lavabit.com>
# Contributor: Matthew Bauer <mjbauer95@gmail.com>

pkgname=libfprint-validity90
pkgver=r111.baab930
pkgrel=1
pkgdesc="Library for fingerprint readers (with Validity90 test driver)"
arch=(i686 x86_64)
url="https://github.com/nmikhailov/Validity90"
license=(LGPL)
depends=(libusb nss pixman gnutls openssl)
makedepends=(git)
groups=(fprint-git fprint)
provides=(libfprint libfprint-git)
conflicts=(libfprint libfprint-git)
source=("git+https://github.com/nmikhailov/Validity90.git")
md5sums=('SKIP')

pkgver() {
  cd Validity90/libfprint

  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd Validity90/libfprint

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd Validity90/libfprint

  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --disable-static
  make
}

package() {
  cd Validity90/libfprint

  make DESTDIR="$pkgdir" install
}