Add page numbers to facing page Skim PDF

-- creates notes on every page in the lower L and lower R for those occasions where the scanner cut off the page numbers

set firstPage to (text returned of (display dialog "Enter Starting Page" default answer "")) as number

set currentPage to firstPage

tell application "Skim"
	set pp to pages of document 1
	repeat with p in items of pp
		tell p
			set pageSize to content bounds
			set leftBox to {(item 1 of pageSize) + 10, (item 4 of pageSize) + 25, (item 1 of pageSize) + 50, (item 4 of pageSize) + 10}
			set rightBox to {(item 3 of pageSize) - 50, (item 4 of pageSize) + 25, (item 3 of pageSize) - 10, (item 4 of pageSize) + 10}
			make new note with properties {bounds:leftBox, type:text note, text:currentPage, font name:"Times", font size:12, line width:0, color:white}
			make new note with properties {bounds:rightBox, type:text note, text:currentPage + 1, font name:"Times", font size:12, line width:0, color:white, alignment:right alignment}
		end tell
		set currentPage to currentPage + 2
	end repeat
end tell